引 言
這篇文章最先發表於2000年07月25日，最後一次修改是在2001年02月07日。這裡再次貼出的目的，一是作為前一階段的完結，所以文章中的錯誤都不作修改；二是希望作為一個新的起點。我准備整理一下至今所積累的浏覽器編程的知識，比較完整地寫出來，與網友共勉。
TWebBrowser編程簡述
摘要：Delphi 3開始有了TWebBrowser構件，不過那時是以ActiveX控件的形式出現的，而且需要自己引入，在其後的4.0和5.0中，它就在封裝好shdocvw.dll之後作為Internet構件組之一出現在構件面板上了。常常聽到有人罵Delphi的幫助做得極差，這次的TWebBrowser又是Microsoft的東東，自然不會好到哪裡去，雖說MSDN上什麼都有，可是內容太過龐雜，如果沒有入口點更是件煩人的事，查找起來給人的感覺大概可以用一句話來形容：非常復雜、復雜非常。
這裡有平時我自己用TWebBrowser做程序的一些心得和上網收集到的部分例子和資料，整理了一下，希望能給有興趣用TWebBrowser編程的朋友帶來些幫助。
１、初始化和終止化（Initialization & Finalization）
大家在執行TWebBrowser的某個方法以進行期望的操作，如ExecWB等的時候可能都碰到過“試圖激活未注冊的丟失目標”或“OLE對象未注冊”等錯誤，或者並沒有出錯但是得不到希望的結果，比如不能將選中的網頁內容復制到剪貼板等。以前用它編程的時候，我發現ExecWB有時侯起作用但有時侯又不行，在Delphi生成的缺省工程主窗口上加入TWebBrowser，運行時並不會出現“OLE對象未注冊”的錯誤。同樣是一個偶然的機會，我才知道OLE對象需要初始化和終止化（懂得的東東實在太少了）。
我用我的前一篇文章《Delphi程序窗口動畫&正常排列平鋪的解決》所說的方法編程，運行時出了上面所說的錯誤，我便猜想應該有OleInitialize之類的語句，於是，找到並加上了下面幾句話，終於搞定！究其原因，我想大概是由於TWebBrowser是一個嵌入的OLE對象而不算是用Delphi編寫的VCL吧。
initialization
OleInitialize(nil);
finalization
try
OleUninitialize;
except
end;
這幾句話放在主窗口所有語句之後，“end.”之前。
--------------------------------------------------------------------------------------------------------
２、EmptyParam
在Delphi 5中TWebBrowser的Navigate方法被多次重載：
procedure Navigate(const URL: WideString); overload;
procedure Navigate(const URL: WideString; var Flags: OleVariant); overload;
procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: OleVariant); overload;
procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: OleVariant; var PostData: OleVariant); overload;
procedure Navigate(const URL: WideString; var Flags: OleVariant; var TargetFrameName: OleVariant; var PostData: OleVariant; var Headers: OleVariant); overload;
而在實際應用中，使用後幾種方法調用時，由於我們很少用到後面幾個參數，但函數聲明又要求是變量參數，一般的做法如下：
var
t:OleVariant;
begin
webbrowser1.Navigate(edit1.text,t,t,t,t);
end;
需要定義變量t（還有很多地方要用到它），很麻煩。其實我們可以用EmptyParam來代替（EmptyParam是一個公用的Variant空變量，不要對它賦值），只需一句話就可以了：
webbrowser1.Navigate(edit1.text,EmptyParam,EmptyParam,EmptyParam,EmptyParam);
雖然長一點，但比每次都定義變量方便得多。當然，也可以使用第一種方式。
webbrowser1.Navigate(edit1.text)
--------------------------------------------------------------------------------------------------------
３、命令操作
常用的命令操作用ExecWB方法即可完成，ExecWB同樣多次被重載：
procedure ExecWB(cmdID: OLECMDID; cmdexecopt: OLECMDEXECOPT); overload;
procedure ExecWB(cmdID: OLECMDID; cmdexecopt: OLECMDEXECOPT; var pvaIn: OleVariant); overload;
procedure ExecWB(cmdID: rOLECMDID; cmdexecopt: OLECMDEXECOPT; var pvaIn: OleVariant; var pvaOut: OleVariant); overload;
打開： 彈出“打開Internet地址”對話框，CommandID為OLECMDID_OPEN（若浏覽器版本為IE5.0，
則此命令不可用）。
另存為：調用“另存為”對話框。
ExecWB(OLECMDID_SAVEAS,OLECMDEXECOPT_DODEFAULT, EmptyParam, EmptyParam);
打印、打印預覽和頁面設置： 調用“打印”、“打印預覽”和“頁面設置”對話框（IE5.5及以上版本才支持打
印預覽，故實現應該檢查此命令是否可用）。
ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_DODEFAULT, EmptyParam, EmptyParam);
if QueryStatusWB(OLECMDID_PRINTPREVIEW)=3 then
ExecWB(OLECMDID_PRINTPREVIEW, OLECMDEXECOPT_DODEFAULT, EmptyParam,EmptyParam);
ExecWB(OLECMDID_PAGESETUP, OLECMDEXECOPT_DODEFAULT, EmptyParam, EmptyParam);
剪切、復制、粘貼、全選： 功能無須多說，需要注意的是：剪切和粘貼不僅對編輯框文字，而且對網頁上的非編輯框文字同樣有效，用得好的話，也許可以做出功能特殊的東東。獲得其命令使能狀態和執行命令的方法有兩種（以復制為例，剪切、粘貼和全選分別將各自的關鍵字替換即可，分別為CUT,PASTE和SELECTALL）：
A、用TWebBrowser的QueryStatusWB方法。
if(QueryStatusWB(OLECMDID_COPY)=OLECMDF_ENABLED) or
OLECMDF_SUPPORTED) then
ExecWB(OLECMDID_COPY, OLECMDEXECOPT_DODEFAULT, EmptyParam, EmptyParam);
B、用IHtmlDocument2的QueryCommandEnabled方法。
var
Doc: IHtmlDocument2;
begin
Doc :=WebBrowser1.Document as IHtmlDocument2;
if Doc.QueryCommandEnabled('Copy') then
Doc.ExecCommand('Copy',false,EmptyParam);
end;
查找： 參考第九條“查找”功能。
--------------------------------------------------------------------------------------------------------
４、字體大小
類似“字體”菜單上的從“最大”到“最小”五項（對應整數0～4，Largest等假設為五個菜單項的名字，Tag 屬性分別設為0～4）。
A、讀取當前頁面字體大小。
var
t: OleVariant;
Begin
WebBrowser1.ExecWB(OLECMDID_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER,
EmptyParam,t);
case t of
4: Largest.Checked :=true;
3: Larger.Checked :=true;
2: Middle.Checked :=true;
1: Small.Checked :=true;
0: Smallest.Checked :=true;
end;
end;
B、設置頁面字體大小。
Largest.Checked :=false;
Larger.Checked :=false;
Middle.Checked :=false;
Small.Checked :=false;
Smallest.Checked :=false;
TMenuItem(Sender).Checked :=true;
t :=TMenuItem(Sender).Tag;
WebBrowser1.ExecWB(OLECMDID_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER,
t,t);
--------------------------------------------------------------------------------------------------------
５、添加到收藏夾和整理收藏夾
const
CLSID_ShellUIHelper: TGUID = '{64AB4BB7-111E-11D1-8F79-00C04FC2FBE1}';
var
p:procedure(Handle: THandle; Path: PChar); stdcall;
procedure TForm1.OrganizeFavorite(Sender: Tobject);
var
H: HWnd;
begin
H := LoadLibrary(PChar('shdocvw.dll'));
if H <> 0 then
begin
p := GetProcAddress(H, PChar('DoOrganizeFavDlg'));
if Assigned(p) then p(Application.Handle, PChar(FavFolder));
end;
FreeLibrary(h);
end;
procedure TForm1.AddFavorite(Sender: TObject);
var
ShellUIHelper: ISHellUIHelper;
url, title: Olevariant;
begin
Title := Webbrowser1.LocationName;
Url := Webbrowser1.LocationUrl;
if Url <> '' then
begin
ShellUIHelper := CreateComObject(CLSID_SHELLUIHELPER) as IShellUIHelper;
ShellUIHelper.AddFavorite(url, title);
end;
end;
用上面的通過ISHellUIHelper接口來打開“添加到收藏夾”對話框的方法比較簡單，但是有個缺陷，就是打開的窗口不是模式窗口，而是獨立於應用程序的。可以想象，如果使用與OrganizeFavorite過程同樣的方法來打開對話框，由於可以指定父窗口的句柄，自然可以實現模式窗口（效果與在資源管理器和IE中打開“添加到收藏夾”對話框相同）。問題顯然是這樣的，上面兩個過程的作者當時只知道shdocvw.dll中DoOrganizeFavDlg的原型而不知道DoAddToFavDlg的原型，所以只好用ISHellUIHelper接口來實現（或許是他不夠嚴謹，認為是否是模式窗口無所謂？）。
下面的過程就告訴你DoAddToFavDlg的函數原型。需要注意的是，這樣打開的對話框並不執行“添加到收藏夾”的操作，它只是告訴應用程序用戶是否選擇了“確定”，同時在DoAddToFavDlg的第二個參數中返回用戶希望放置Internet快捷方式的路徑，建立.Url文件的工作由應用程序自己來完成。
procedure TForm1.AddFavorite(IE: TEmbeddedWB);
procedure CreateUrl(AUrlPath, AUrl: PChar);
var
URLfile: TIniFile;
begin
URLfile := TIniFile.Create(String(AUrlPath));
RLfile.WriteString('InternetShortcut', 'URL', String(AUrl));
RLfile.Free;
end;
var
AddFav: function(Handle: THandle;
UrlPath: PChar; UrlPathSize: Cardinal;
Title: PChar; TitleSize: Cardinal;
FavIDLIST: pItemIDList): Bool; stdcall;
FDoc: IHtmlDocument2;
UrlPath, url, title: array[0..MAX_PATH] of char;
H: HWnd;
pidl: pItemIDList;
FRetOK: Bool;
begin
FDoc := IHtmlDocument2(IE.Document);
if FDoc = nil then exit;
StrPCopy(Title, FDoc.Get_title);
StrPCopy(url, FDoc.Get_url);
if Url <> '' then
begin
H := LoadLibrary(PChar('shdocvw.dll'));
if H <> 0 then
begin
SHGetSpecialFolderLocation(0, CSIDL_FAVORITES, pidl);
AddFav := GetProcAddress(H, PChar('DoAddToFavDlg'));
if Assigned(AddFav) then
FRetOK :=AddFav(Handle, UrlPath, Sizeof(UrlPath), Title, Sizeof(Title), pidl)
end;
FreeLibrary(h);
if FRetOK then
CreateUrl(UrlPath, Url);
end
end;
--------------------------------------------------------------------------------------------------------
６、使WebBrowser獲得焦點
TWebBrowser非常特殊，它從TWinControl繼承來的SetFocus方法並不能使得它所包含的文檔獲得焦點，從而不能立即使用Internet Explorer本身具有得快捷鍵，解決方法如下：<
procedure TForm1.SetFocusToDoc;
begin
if WebBrowser1.Document <> nil then
with WebBrowser1.Application as IOleobject do
DoVerb(OLEIVERB_UIACTIVATE, nil, WebBrowser1, 0, Handle, GetClIEntRect);
end;
除此之外，我還找到一種更簡單的方法，這裡一並列出：
if WebBrowser1.Document <> nil then
IHTMLWindow2(IHtmlDocument2(WebBrowser1.Document).ParentWindow).focus
剛找到了更簡單的方法，也許是最簡單的：
if WebBrowser1.Document <> nil then
IHtmlWindow4(WebBrowser1.Document).focus
還有，需要判斷文檔是否獲得焦點這樣來做：
if IHtmlWindow4(WebBrowser1.Document).hasfocus then
--------------------------------------------------------------------------------------------------------
７、點擊“提交”按鈕
如同程序裡每個窗體上有一個“缺省”按鈕一樣，Web頁面上的每個Form也有一個“缺省”按鈕——即屬性為“Submit”的按鈕，當用戶按下回車鍵時就相當於鼠標單擊了“Submit”。但是TWebBrowser似乎並不響應回車鍵，並且，即使把包含TWebBrowser的窗體的KeyPrevIEw設為True，在窗體的KeyPress事件裡還是不能截獲用戶向TWebBrowser發出的按鍵。
我的解決辦法是用ApplicatinEvents構件或者自己編寫TApplication對象的OnMessage事件，在其中判斷消息類型，對鍵盤消息做出響應。至於點擊“提交”按鈕，可以通過分析網頁源代碼的方法來實現，不過我找到了更為簡單快捷的方法，有兩種，第一種是我自己想出來的，另一種是別人寫的代碼，這裡都提供給大家，以做參考。
A、用SendKeys函數向WebBrowser發送回車鍵
在Delphi 5光盤上的InfoExtrasSendKeys目錄下有一個SndKey32.pas文件，其中包含了兩個函數SendKeys和AppActivate，我們可以用SendKeys函數來向WebBrowser發送回車鍵，我現在用的就是這個方法，使用很簡單，在WebBrowser獲得焦點的情況下（不要求WebBrowser所包含的文檔獲得焦點），用一條語句即可：
Sendkeys('~',true);// press RETURN key
SendKeys函數的詳細參數說明等，均包含在SndKey32.pas文件中。
B、在OnMessage事件中將接受到的鍵盤消息傳遞給WebBrowser。
procedure TForm1.ApplicationEvents1Message(var Msg: TMsg; var Handled: Boolean);
{fixes the malfunction of some keys within webbrowser control}
const
StdKeys = [VK_TAB, VK_RETURN]; { standard keys }
ExtKeys = [VK_DELETE, VK_BACK, VK_LEFT, VK_RIGHT]; { extended keys }
fExtended = $01000000; { extended key flag }
begin
Handled := False;
with Msg do
if ((Message >= WM_KEYFIRST) and (Message <= WM_KEYLAST)) and
((wParam in StdKeys) or
{$IFDEF VER120}(GetKeyState(VK_CONTROL) < 0) or {$ENDIF}
(wParam in ExtKeys) and
((lParam and fExtended) = fExtended)) then
try
if IsChild(Handle, hWnd) then { handles all browser related messages }
begin
with {$IFDEF VER120}Application_{$ELSE}Application{$ENDIF} as
IOleInPlaceActiveObject do
Handled := TranslateAccelerator(Msg) = S_OK;
if not Handled then
begin
Handled := True;
TranslateMessage(Msg);
DispatchMessage(Msg);
end;
end;
except
end;
end; // MessageHandler
（此方法來自EmbeddedWB.pas）
--------------------------------------------------------------------------------------------------------
８、直接從TWebBrowser得到網頁源碼及Html
下面先介紹一種極其簡單的得到TWebBrowser正在訪問的網頁源碼的方法。一般方法是利用TWebBrowser控件中的Document對象提供的IPersistStreamInit接口來實現，具體就是：先檢查WebBrowser.Document對象是否有效，無效則退出；然後取得IPersistStreamInit接口，接著取得HTML源碼的大小，分配全局堆內存塊，建立流，再將Html文本寫到流中。程序雖然不算復雜，但是有更簡單的方法，所以實現代碼不再給出。其實基本上所有IE的功能TWebBrowser都應該有較為簡單的方法來實現，獲取網頁源碼也是一樣。下面的代碼將網頁源碼顯示在Memo1中。
Memo1.Lines.Add(IHtmlDocument2(WebBrowser1.Document).Body.OuterHtml);
同時，在用TWebBrowser浏覽Html文件的時候要將其保存為文本文件就很簡單了，不需要任何的語法解析工具，因為TWebBrowser也完成了，如下：
Memo1.Lines.Add(IHtmlDocument2(WebBrowser1.Document).Body.OuterText);
--------------------------------------------------------------------------------------------------------
９、“查找”功能
查找對話框可以在文檔獲得焦點的時候通過按鍵Ctrl-F來調出，程序中則調用IOleCommandTarget對象的成員函數Exec執行OLECMDID_FIND操作來調用，下面給出的方法是如何在程序中用代碼來做出文字選擇，即你可以自己設計查找對話框。
var
Doc: IHtmlDocument2;
TxtRange: IHtmlTxtRange;
begin
Doc :=WebBrowser1.Document as IHtmlDocument2;
Doc.SelectAll; //此處為簡寫，選擇全部文檔的方法請參見第三條命令操作
//這句話尤為重要，因為IHtmlTxtRange對象的方法能夠操作的前提是
//Document已經有一個文字選擇區域。由於接著執行下面的語句，所以不會
//看到文檔全選的過程。
TxtRange :=Doc.Selection.CreateRange as IHtmlTxtRange;
TxtRange.FindText('Text to be searched',0.0);
TxtRange.Select;
end;
還有，從Txt.Get_text可以得到當前選中的文字內容，某些時候是有用的。
--------------------------------------------------------------------------------------------------------
１０、提取網頁中所有鏈接
這個方法來自大富翁論壇hopfIEld朋友的對一個問題的回答，我本想自己試驗，但總是沒成功。
var
doc:IHtmlDocument2;
all:IHtmlElementCollection;
len,i:integer;
item:OleVariant;
begin
doc:=WebBrowser1 .Document as IHtmlDocument2;
all:=doc.Get_links; //doc.Links亦可
len:=all.length;
for i:=0 to len-1 do begin
item:=all.item(i,varempty); //EmpryParam亦可
memo1.lines.add(item.href);
end;
end;
--------------------------------------------------------------------------------------------------------
１１、設置TWebBrowser的編碼
為什麼我總是錯過很多機會？其實早就該想到的，但是一念之差，便即天壤之別。當時我要是肯再多考慮一下，多試驗一下，這就不會排到第１１條了。下面給出一個函數，搞定，難以想象的簡單。
procedure SetCharSet(AWebBrowser: TWebBrowser; ACharSet: String);
var
RefreshLevel: OleVariant;
Begin
IHtmlDocument2(AWebBrowser.Document).Set_CharSet(ACharSet);
RefreshLevel :=7; //這個7應該從注冊表來，幫助有Bug。
AWebBrowser.Refresh2(RefreshLevel);
End;
--------------------------------------------------------------------------------------------------------
１２、在TWebBrowser中輸入字符時激活菜單的解決
許多朋友編程的時候都遇到了這樣一個問題，在TWebBrowser中輸入時，鍵入的字符如果與菜單（用ToolBar做的菜單）的加速鍵相同就會激活菜單。有朋友解決辦法是把加速鍵前面的“&”符號去掉，使得字符失去“加速”功能，這種方法未嘗不可，只不過顯得不夠“專業”。其實略加分析我們就可以想到，是ToolBar搶先處理了按鍵（因為ToolBar本身就設計為用來實現具有Windows新風格的菜單），所以只需要修改ToolBar的源代碼中處理菜單按鍵的那部分代碼即可，方法如下：
１）、在$(Delphi)sourcevcl目錄下找到comctrls.pas，拷貝到自己的程序所在目錄，然後打開它。
２）、找到TToolBar.CMDialogChar過程，把過程體注釋掉（如果你願意的話，可以修改它）。
３）、重新編譯自己的程序。
怎麼樣，是不是很簡單？但它確實有效。
--------------------------------------------------------------------------------------------------------
１３、去掉TWebBrowser的滾動條
缺省地，TWebBrowser是滾動條的，雖然我們可以在網頁中設置不需要滾動條，不過，有些時候可能會有特殊的要求，比如，網頁是有滾動條的，但又想去掉它該怎麼辦呢？很簡單，下面給出兩行代碼，都可以達到目的，可謂殊途同歸。
１）、IHTMLBodyElementDisp(IHtmlDocument2(WebBrowser1.document).body).scroll:= 'no';
２）、WebBrowser1.oleobject.Document.body.Scroll := 'no';
注：第一種方法需要在uses部分加上MSHTML_TLB或者MSHtml。
--------------------------------------------------------------------------------------------------------
１４、通過IUniformResourceLocator接口建立Internet快捷方式
前面說到的顯示“添加到收藏夾”模式對話框的方法中舉了一個建立Internet快捷方式的例子，就其本身來說不太規范，屬於取巧一類的方法。下面介紹的方法是通過接口來實現的。
procedure CreateIntShotCut(aFileName, aURL: PChar);
var IURL: IUniformResourceLocator;
PersistFile: IPersistfile;
begin
if Succeeded(CoCreateInstance(CLSID_InternetShortcut,
nil,
CLSCTX_INPROC_SERVER,
IID_IUniformResourceLocator,
IURL)) then
begin
IUrl.SetURL(aURL, 0);
Persistfile := IUrl as IPersistFile;
PersistFile.Save(StringToOleStr(aFileName), False);
end;
end;
其中IUniformResourceLocator接口的聲明在IeConst.pas中，IeConst.pas可以在網站IE & Delphi找到； IPersistfile接口的聲明在ActiveX.pas中。
注：這個函數的AURL參數必須包含協議前綴，如“Http://eagleboost.myrice.com”。
