多線程編程(1)-先入門再說

多線程應該是編程工作者的基礎技能, 但這個基礎對我來講的確有點難(起碼昨天以前是這樣).

開始本應該是一篇洋洋灑灑的文字, 不過我還是提倡先做起來, 在嘗試中去理解.

先試試這個:

procedure TForm1.Button1Click(Sender: TObject);
var
　i: Integer;
begin
　for i := 0 to 500000 do
　begin
　　Canvas.TextOut(10, 10, IntToStr(i));
　end;
end;

上面程序運行時, 我們的窗體基本是 "死" 的, 可以在你在程序運行期間拖動窗體試試...

Delphi 為我們提供了一個簡單的辦法(Application.ProcessMessages)來解決這個問題:

procedure TForm1.Button1Click(Sender: TObject);
var
　i: Integer;
begin
　for i := 0 to 500000 do
　begin
　　Canvas.TextOut(10, 10, IntToStr(i));
　　Application.ProcessMessages;
　end;
end;

這個 Application.ProcessMessages; 一般用在比較費時的循環中, 它會檢查並先處理消息隊列中的其他消息.

但這算不上多線程, 譬如: 運行中你拖動窗體, 循環會暫停下來...

在使用多線程以前, 讓我們先簡單修改一下程序:

function MyFun: Integer;
var
　i: Integer;
begin
　for i := 0 to 500000 do
　begin
　　Form1.Canvas.Lock;
　　Form1.Canvas.TextOut(10, 10, IntToStr(i));
　　Form1.Canvas.Unlock;
　end;
　Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
　MyFun;
end;

細數上面程序的變化:

1、首先這還不是多線程的, 也會讓窗體假 "死" 一會;

2、把執行代碼寫在了一個函數裡, 但這個函數不屬於 TForm1 的方法, 所以使用 Canvas 是必須冠以名稱(Form1);

3、既然是個函數, (不管是否必要)都應該有返回值;

4、使用了 500001 次 Lock 和 Unlock.

Canvas.Lock 好比在說: Canvas(繪圖表面)正忙著呢, 其他想用 Canvas 的等會;

Canvas.Unlock : 用完了, 解鎖!

在 Canvas 中使用 Lock 和 Unlock 是個好習慣, 在不使用多線程的情況下這無所謂, 但保不准哪天程序會擴展為多線程的; 我們現在學習多線程, 當然應該用.

在 Delphi 中使用多線程有兩種方法: 調用 API、使用 TThread 類; 使用 API 的代碼更簡單.

function MyFun(p: Pointer): Integer; stdcall;
var
　i: Integer;
begin
　for i := 0 to 500000 do
　begin
　　Form1.Canvas.Lock;
　　Form1.Canvas.TextOut(10, 10, IntToStr(i));
　　Form1.Canvas.Unlock;
　end;
　Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
　ID: THandle;
begin
　CreateThread(nil, 0, @MyFun, nil, 0, ID);
end;

代碼分析:

CreateThread 一個線程後, 算上原來的主線程, 這樣程序就有兩個線程、是標准的多線程了;

CreateThread 第三個參數是函數指針, 新線程建立後將立即執行該函數, 函數執行完畢, 系統將銷毀此線程從而結束多線程的故事.

CreateThread 要使用的函數是系統級別的, 不能是某個類(譬如: TForm1)的方法, 並且有嚴格的格式(參數、返回值)要求, 不管你暫時是不是需要都必須按格式來;

因為是系統級調用, 還要綴上 stdcall, stdcall 是協調參數順序的, 雖然這裡只有一個參數沒有順序可言, 但這是使用系統函數的慣例.

CreateThread 還需要一個 var 參數來接受新建線程的 ID, 盡管暫時沒用, 但這也是格式; 其他參數以後再說吧.

這樣一個最簡單的多線程程序就出來了, 咱們再用 TThread 類實現一次

type
　TMyThread = class(TThread)
　protected
　　procedure Execute; override;
　end;
procedure TMyThread.Execute;
var
　i: Integer;
begin
　FreeOnTerminate := True; {這可以讓線程執行完畢後隨即釋放}
　for i := 0 to 500000 do
　begin
　　Form1.Canvas.Lock;
　　Form1.Canvas.TextOut(10, 10, IntToStr(i));
　　Form1.Canvas.Unlock;
　end;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
　TMyThread.Create(False);
end;

TThread 類有一個抽象方法(Execute), 因而是個抽象類, 抽象類只能繼承使用, 上面是繼承為 TMyThread.

繼承 TThread 主要就是實現抽象方法 Execute(把我們的代碼寫在裡面), 等我們的 TMyThread 實例化後, 首先就會執行 Execute 方法中的代碼.

按常規我們一般這樣去實例化:

procedure TForm1.Button1Click(Sender: TObject);
var
　MyThread: TMyThread;
begin
　MyThread := TMyThread.Create(False);
end;

因為 MyThread 變量在這裡毫無用處(並且編譯器還有提示), 所以不如直接寫做 TMyThread.Create(False);

我們還可以輕松解決一個問題, 如果: TMyThread.Create(True) ?

這樣線程建立後就不會立即調用 Execute, 可以在需要的時候再用 Resume 方法執行線程, 譬如:

procedure TForm1.Button1Click(Sender: TObject);
var
　MyThread: TMyThread;
begin
　MyThread := TMyThread.Create(True);
　MyThread.Resume;
end;
//可簡化為:
procedure TForm1.Button1Click(Sender: TObject);
begin
　with TMyThread.Create(True) do Resume;
end;

使用 TThread 類時, Delphi 有提供的模板, 但用 IDE 寫代碼很方便, 我重寫一遍錄下來給大家看:

期間使用了 Ctrl+J、Shift+Ctrl+C、Ctrl+Alt+P 等快捷鍵.

重要的修正與補充: 在 TThread 類的例子中, 應該有這句: FreeOnTerminate := True; (原來漏掉, 代碼中已加上; 但動畫加不上了).

先說它什麼意思:

類 Create 了就要 Free;

但 TThread(的子類) 有特殊性, 很多時候我們不能確定新建的線程什麼時候執行完(也就是什麼時候該釋放);

如果線程執行完畢自己知道釋放就好了, 所以 TThread 給了一個布爾屬性 FreeOnTerminate, 如果為 True, 線程執行完畢後就會自釋放.

我怎麼會忽略了這麼重要的問題呢? 原因有二:

1、我一直在追求最精煉的代碼;

2、我手頭上不只一本書上介紹說: FreeOnTerminate 的默認值是 True(錯誤!), 經落實, 應該是 False, 起碼在 Delphi 2007 和 2009 中是這樣; 或許以前的某個版本和現在不一樣.