XML（eXtensible Markup Language可擴展標志語言）在近幾年的信息類雜志、網站上可謂是最搶眼的一詞。大大小小的信息產品都爭相和它搭上關系，唯恐趕不及這輛快車。有著良好口碑的寶藍 （Borland)系列開發平台也不例外，從6.0版開始就集成了XML組件包，因其使用MSXMLDom解析器，相比於此前廣泛應用的XMLParser解析器，MSXMLDom更顯規范、中文兼容性更好（元素名、屬性名均支持中文），很受開發者青睐。為幫助初學者快速掌握Delphi中的XML編程，筆者特寫此文，以供交流。
筆者通過一個讀寫XML文件的實例來說明XML編程的各個步驟，只需讀者有結點、元素、屬性的基本概念就能容易的理解本文。筆者所要讀入的XML文件結構如下所示，命名為Input.xml。
＜?xml version="1.0" encoding="GB2312"?＞
＜學生花名冊＞
＜學生 性別 = "男"＞
＜姓名＞李華＜/姓名＞
＜年齡＞14＜/年齡＞
＜電話＞6287555＜/電話＞
＜/學生＞
＜學生 性別 = "男"＞
＜姓名＞張三＜/姓名＞
＜年齡＞16＜/年齡＞
＜電話＞8273425＜/電話＞
＜/學生＞
＜/學生花名冊＞
Input.xml文件的第一行是XML的版本說明，屬性encoding宣告使用何種字符集建立，默認以Unicode 編碼（UTF-8 或UTF-16），這裡用中文GB2312碼。第二行“＜學生花名冊＞“是根元素。下面定義了兩個學生元素,學生下面嵌套了三個子元素，是對學生的進一步說明。與之相對應的，我們在Delphi中定義如下的學生數據結構,"//"後面的文字是對變量或語句的說明，下同。
TStudent = class {學生}
sex : string; //學生性別
name : string; //學生姓名
age : integer; //學生年齡
phone: string; //電話號碼
end;
為了讀寫，我們需要放置兩個TXMLDocument控件，在Delphi VCL面板的Internet標簽頁裡那個標有XML字樣的控件就是，當然此控件也可以動態創建，但需要包含必要的文件，這裡為簡單起見，我們直接放置在窗體上，分別命名為InXMLDoc和OutXMLDoc，InXMLDoc用於調入Input.xml文件，OutXMLDoc用於暫存輸出到Output.xml的文檔。
在窗體上放個按鈕，我們把測試代碼直接放置在按鈕的單擊事件裡。先定義幾個變量，用來保存臨時信息，如下所示：
Root : IXMLNode; //指向XML根結點
Parent_Node: IXMLNode; //指向學生結點
Child_node : IXMLNode; //指向學生的子結點
Student : TStudent; //存單個學生信息
List : TList; //存學生列表
i : integer; //循環變量
我們先來讀入XML文件，代碼如下：
List := TList.Create; //初始化列表
InXMLDoc.LoadFromFile('Input.xml'); //調入Input.xml文件
Root := InXMLDoc.DocumentElement; //取XML文件的根結點，即“＜學生花名冊＞”
Parent_Node := Root.ChildNodes.First; //使Parent_Node指向學生結點
while (Parent_Node ＜＞ nil) do //循環取多個學生，可再多加幾個學生信息測試
begin
if (Parent_Node.NodeName = '學生') then //判斷是否為學生結點
begin
Student := TStudent.Create; //新建一個學生的結構信息
Student.sex := Parent_Node.Attributes['性別']; //取學生的性別屬性
Child_Node := Parent_Node.ChildNodes.First;
//使Child_Node指向該學生的第一個子結點信息
while (Child_Node ＜＞ nil) do //循環取學生的各個子各點
begin
if (Child_Node.NodeName = '姓名') then //判斷是否為姓名結點
Student.name := Child_Node.Text //取姓名結點的值，取於name字段中
else if (Child_Node.NodeName = '年齡') then //此行起後四行與前兩行類似
Student.age := StrToInt(Child_Node.Text)
else if (Child_Node.NodeName = '電話') then
Student.phone := Child_Node.Text;
Child_Node := Child_Node.NextSibling; //順序取下一個學生的子結點信息
end;
List.Add(Student); //把一個學生信息加入列表
end;
Parent_Node := Parent_Node.NextSibling; //順序取下一個學生信息
end;
到這兒，所有的學生信息都已存到List列表裡面了，讀者可以跟蹤代碼測試。
下面我們把List裡的臨時學生信息存到Output.xml文件裡，代碼如下：
OutXMLDoc.Active := true; //激活OutXMLDoc,自動初始化空的XML文檔
OutXMLDoc.Encoding := 'GB2312'; //設置字符集
Root := OutXMLDoc.AddChild('學生花名冊'); //建根結點
for i := 0 to List.Count - 1 do //循環取各個學生信息
begin
Student := List.Items[i]; //順序取一個學生信息
if (Student ＜＞ nil) then
begin
Parent_Node := Root.AddChild('學生'); //根結點後添加一個學生結點
Parent_Node.Attributes['性別'] := Student.sex; //給學生結點設置性別屬性
Child_Node := Parent_Node.AddChild('姓名'); //學生結點後添加一個姓名結點
Child_Node.Text := Student.name; //設置姓名的文本值
Child_Node := Parent_Node.AddChild('年齡'); //此行起後四行與前兩行類似
Child_Node.Text := IntToStr(Student.age);
Child_Node := Parent_Node.AddChild('電話');
Child_Node.Text := Student.phone;
end;
end;
OutXMLDoc.SaveToFile('Output.xml'); //把組織好的XML文檔存於Output.xml文件中
OutXMLDoc.Active := false; //鈍化（關閉）OutXMLDoc
List.Free; //最後釋放保存臨時學生信息的列表
好了，看看Input.xml和Output.xml內容是不是一樣。是不是很簡單呢？其實在C++ Builder也有相同的組件，只需將Pascal語法轉換成C++語法，上面的代碼就完全可以用了。
