Fast Report是一個經典的報表控件，不過其導出功能只支持導出到磁盤文件，而此項目為了避開權限的限制和出於服務器安全的需要，要求將Fast Report生成的報表導出到內存流，所以要修改Fast Report源碼。
Fast Report2.5的導出函數在FR_Class文件中聲明，參考此函數，可以很輕易的寫出導出到內存流的函數：
//添加導出到內存流的支持 --Conch 2007-09-10--
procedure TfrReport.ExportToStream(Filter: TfrExportFilter; Stream: TMemoryStream);
var
s: String;
Flag, NeedConnect: Boolean;
begin
DocMode := dmPrinting;
FCurrentFilter := Filter;
if (Preview <> nil) and (EMFPages.Count = 0) then
begin
Preview.Disconnect;
NeedConnect := True;
end
else
NeedConnect := False;
Flag := True;
if Assigned(FCurrentFilter.OnBeforeExport) then
FCurrentFilter.OnBeforeExport(FCurrentFilter.FileName, Flag);
FCurrentFilter.Stream := Stream;
CurReport := Self;
MasterReport := Self;
SavedAllPages := EMFPages.Count;
FCurrentFilter.OnBeginDoc;
ExportBeforeModal(Self);
if Assigned(FCurrentFilter.OnAfterExport) then
FCurrentFilter.OnAfterExport(FCurrentFilter.FileName);
if NeedConnect then
Preview.Connect(Self);
FCurrentFilter := nil;
end;
同樣，TfrHTML2Export控件是將CSS文件與HTML分開保存的，這樣使得內存流中的HTML內容因缺少CSS而無法顯示，故此要修改TfrHTML2Export.OnEndDoc函數。從該函數中找到SaveStringToFile(ImageFolderFull + '' + CSSFile, s)這一句（FR2.5在第461行），改為：
if FileName <> '' then
SaveStringToFile(ImageFolderFull + '' + CSSFile, s)
else begin
s := '<style type=''text/css''>' + LF + s + LF + '</style>' + LF;
Stream.Write(s[1], Length(s));
end;
其它版本或其它導出控件可按此方法修改（導出Excel控件因使用OLE技術調用Excel組件，只能保存到磁盤文件），修改後的OnEndDoc函數如下：
procedure TfrHTML2Export.OnEndDoc;
var
s : string;
i, j : integer;
Page : THPage;
LastBottom : integer;
CSSFile : string;
CSSFilePrint : string;
NavFile : string;
// DefaultStyle : THStyle;
// Style : THStyle;
h1, h2 : string;
MaxWidth : integer;
MinLeftMargin : integer;
begin
if Navigator = nil then Exit;
if FPages.Count = 0 then Exit;
if FStyles.Count > 0 then
begin
s := '';
CSSFilePrint := ChangeFileExt(ExtractFileName(FileName), '_print.css');
if Navigator.Position <> [] then
s := s + Navigator.GetStyleHTML(true);
if s <> '' then
SaveStringToFile(ImageFolderFull + '' + CSSFilePrint, s);
{----------------------------}
CSSFile := ChangeFileExt(ExtractFileName(FileName), '.css');
{DefaultStyle := nil;
for i := 0 to FStyles.Count - 1 do
begin
Style := THStyle(FStyles[i]);
if not (Style is THStyleFrame) or
(THStyleFrame(Style).FFillColor = $1FFFFFFF) then
if (DefaultStyle = nil) or (Style.FCount > DefaultStyle.FCount) then
DefaultStyle := THStyle(FStyles[i]);
end;
if DefaultStyle <> nil then
DefaultStyle.SetDefault;}
//s := 'img' + LF + '{' + LF + 'border: 0px solid #000000;' + LF + '}' + LF;
s := 'span' + LF + '{' + LF + 'position: absolute;' + LF + '}' + LF +
'img' + LF + '{' + LF + 'position: absolute;' + LF + '}' + LF +
'.page_break' + LF + '{' + LF + 'page-break-before: always;' + LF + '}' + LF;
for i := 0 to FStyles.Count - 1 do
s := s + THStyle(FStyles[i]).GetHtml + LF;
if {(FPages.Count > 1) and} (Navigator.Position <> []) then
s := s + Navigator.GetStyleHTML(false);
//配合導出到內存流功能，將CSS內容直接寫到流中 --Conch--
if FileName <> '' then
SaveStringToFile(ImageFolderFull + '' + CSSFile, s)
else begin
s := '<style type=''text/css''>' + LF + s + LF + '</style>' + LF;
Stream.Write(s[1], Length(s));
end;
{----------------------------}
end;
if FMultiPage and (FNavigator.Position <> []) then
begin
if Navigator.InFrame and Navigator.WideInFrame then
begin
MaxWidth := Screen.Width - 20;
MinLeftMargin := 0;
end
else begin
MaxWidth := 0;
MinLeftMargin := High(integer);
for j := 0 to FPages.Count - 1 do
begin
Page := THPage(FPages[j]);
if Page.Width - Page.RightMargin > MaxWidth then
MaxWidth := Page.Width - Page.RightMargin;
if Page.LeftMargin < MinLeftMargin then
MinLeftMargin := Page.LeftMargin;
end;
if MaxWidth + MinLeftMargin > Screen.Width then
MaxWidth := Screen.Width - MinLeftMargin;
end;
FNavigator.BuildItems(MaxWidth);
if FNavigator.InFrame then
begin
NavFile := ChangeFileExt(ExtractFileName(FileName), '') + '_' +
NavigatorFilePostfix + '_0.html';
if npTop in Navigator.Position then
h1 := Format('%dpx,', [Navigator.GetHeight])
else
h1 := '';
if npBottom in Navigator.Position then
h2 := Format(', %dpx', [Navigator.GetHeight])
else
h2 := '';
s := Format(HTMLHeader, [CurReport.Title, CSSFile, CSSFilePrint]) +
Format('<frameset rows="%s *%s" framespacing="0" frameborder="0" border="0">',
[h1, h2]) + LF;
if npTop in Navigator.FPosition then
s := s + Format('<frame src="%s" name="NAVIGATOR_TOP" scrolling="no" ' +
'marginwidth="0" marginheight="0">', [ImageFolder + '/' + NavFile]) + LF;
s := s + Format('<frame src="%s" name="%s" scrolling="yes" marginwidth="0" ' +
'marginheight="0">', [ImageFolder + '/' + THPage(FPages[0]).GetName,
PageFrame]) + LF;
if npBottom in Navigator.FPosition then
s := s + Format('<frame src="%s" name="NAVIGATOR_BOTTOM" scrolling="no" ' +
'marginwidth="0" marginheight="0">', [ImageFolder + '/' + NavFile]) + LF;
s := s + '</frameset>' + LF + HTMLFooter;
Stream.Write(s[1], Length(s));
for j := 0 to FNavigator.FItems.Count - 1 do
begin
s := Format(HTMLHeader, [CurReport.Title, CSSFile, CSSFilePrint]);
s := s + Navigator.GetHTML(TNavigatorItem(FNavigator.FItems[j]).MinPage,
0, MinLeftMargin, MaxWidth, true) + HTMLFooter;
NavFile := ChangeFileExt(ExtractFileName(FileName), '') + '_' +
NavigatorFilePostfix + '_' + IntToStr(j) + '.html';
SaveStringToFile(ImageFolderFull + '' + NavFile, s);
end;
end;
end;
LastBottom := 5;
for j := 0 to FPages.Count - 1 do
begin
Page := THPage(FPages[j]);
if FMultiPage then
begin
if (j = 0) and (not Navigator.InFrame or (Navigator.Position = [])) then
s := Format(HTMLHeader, [CurReport.Title, ImageFolder + '/' + CSSFile,
ImageFolder + '/' + CSSFilePrint])
else
s := Format(HTMLHeader, [CurReport.Title, CSSFile, CSSFilePrint]);
LastBottom := 5;
if (FNavigator.Position <> []) and FNavigator.InFrame then
begin
s := s + Page.GetHTML(LastBottom, 0) + HTMLFooter; //!!!!!!!!!!!!!!!!!!!!
SaveStringToFile(ImageFolderFull + '' + Page.GetName, s);
end
else begin
if (FPages.Count > 1) and (npTop in Navigator.Position) then
begin
s := s + Navigator.GetHTML(Page.ID, LastBottom, Page.LeftMargin,
Page.Width - Page.RightMargin, false);
Inc(LastBottom, Navigator.GetHeight + 15);
end;
s := s + Page.GetHTML(LastBottom, 0);
if (FPages.Count > 1) and (npBottom in Navigator.Position) then
s := s + Navigator.GetHTML(Page.ID, Page.Height + LastBottom +
{Page.BottomMargin} + 5, Page.LeftMargin, Page.Width - Page.RightMargin, false);
s := s + HTMLFooter;
if j = 0 then
Stream.Write(s[1], Length(s))
else
SaveStringToFile(ImageFolderFull + '' + Page.GetName, s);
end;
end
else begin
s := Page.GetHTML(LastBottom, 0);
if j = 0 then
s := Format(HTMLHeader, [CurReport.Title, ImageFolder + '/' + CSSFile,
ImageFolder + '/' + CSSFilePrint]) + s;
Stream.Write(s[1], Length(s));
Inc(LastBottom, Page.Height);
end;
end;
if not FMultiPage then
begin
s := HTMLFooter;
Stream.Write(s[1], Length(s));
end;
ClearListWithFree(FNavigator.FItems);
ClearListWithFree(FStyles);
ClearListWithFree(FPages);
end;
經修改後就可以直接用FrReport1.ExportToStream(ex{TfrHTML2Export}, Stream{TMemoryStream});將報表導出到內存流了。
