Java程序員ActionScript 3入門

我們還是勇敢面對吧：客戶端對於Java程序員來說，一直都不是個友好的地方 。Java在客戶端的技術，包括applet、Swing和JavaFX到目前為止只取得了有限的 成績。JavaScript除了它的名字外，幾乎沒有什麼地方像Java語言。而Adobe Flash呢，它看起來的確像JavaScript，真的嗎？也許在幾年前說Flash就像 JavaScript一樣是可以理解的，但隨著 ActionScript 3的出現，一切都改變了。 而且我相信你會喜歡它的很多東西。

首先，ActionScript這門針對Adobe Flex和Flash的編程語言，現在是強類型 的了。它也是一流的面向對象語言，包括有類和接口。它還擁有你在Java中找不 到的東西——特別地，它包含屬性的get和set方法，以及一個叫做ECMAScript for XML（E4X）的語言擴展，可以將任何XML文檔轉換成對象，這樣你就可以通過 “.”操作符直接引用它們，就跟普通對象一樣。

這篇文章會引領你浏覽ActionScript的基礎內容，以及展示它與你所熟悉的 Java環境的不同。到最後，你就會放棄你對ActionScript 的任何偏見，並開始有 興趣把玩它。關於Flex、Flash和ActionScript的最偉大的事情之一就是它們完全 是免費的。只要下載了Adobe Flex Builder 3就可以開始了。Flex Builder是一 個復雜的集成開發環境（IDE），而且不是免費的，但它用於構建Flash應用的 Flex軟件開發工具包（SDK）是完全免費的。

對閱讀本文章的語言發燒友的一句忠告是：我並不是個語言教師，因此我可能 忽略掉一些語言的細節。我也不會在這篇文章中演示ActionScript 3的所有內容 。如果你的確需要這方面的內容，有很多非常棒的ActionScript 3的書籍。我能 給予你的就是你對這門語言的初次的感覺。讓我們開始吧。

類和接口

就和Java一樣，在ActionScript 3中一切皆是對象。雖然有一些基本類型，比 如integer，但除了這些，一切皆是對象。類似地，就像Java一樣，ActionScript 也有命名空間和包，比如com.jherrington.animals，其表示了company/jack herrington/animal下的類。你可以把類放到缺省的命名空間，但更好的方法是由 你自己來控制自己的命名空間。

要定義一個類，你要使用class關鍵字，這也跟Java一樣。請看示例：

package com.jherrington.animals
{
　　 public class Animal
　　 {
　　　　 public function Animal()
　　　　 {
　　　　 }
　　 }
}

在這個例子中，我定義了一個Animal類，以及什麼也沒干的構造函數。我還可 以很容易地添加一些成員變量並完善這個構造函數，請看示例：

package com.jherrington.animals
{
　　 public class Animal
　　 {
　　　　 public var name:String = "";
　　　　 private var age:int = 0;
　　　　 private function Animal( _name:String, _age:int = 30 )
　　　　 {
　　　　　　 name = _name;
　　　　　　 age = _age;
　　　　 }
　　 }
}

這裡，我給一個Animal對象定義了兩個成員變量：name，一個公有的字符串， 以及age，一個私有的整數。（很明顯，小動物們對於它們的年齡都很害羞。:) ）構造函數可以接受一個或兩個參數：要麼是單獨的name，要麼name和age。你也 可以在函數聲明中為參數提供缺省的值。

你會注意到這裡的類型定義是跟Java相反的。在Java中，類型在變量之前；而 在ActionScript中，類型在變量之後。這是因為強類型定義是追加到 ActionScript上的。所以為了支持舊的、沒有定義類型的代碼，類型就需要放在 變量名的後面。

讓我添加一些方法來擴展這個示例：

package com.jherrington.animals
{
　　 import flash.geom.Point;
　　 public class Animal
　　 {
　　　　 public var name:String = "";
　　　　 private var age:int = 0;
　　　　 private var location:Point = new Point(0,0);
　　　　 public function Animal( _name:String, _age:int = 30 )
　　　　 {
　　　　　　 name = _name;
　　　　　　 age = _age;
　　　　 }
　　　　 public function moveTo( x:int, y:int ) : void {
　　　　　　 location.x = x;
　　　　　　 location.y = y;
　　　　 }
　　　　 public function getLocation( ) : Point {
　　　　　　 return location;
　　　　 }
　　 }
}

正如你所看到的，我又添加了一個私有成員變量location，類型是我從Flash 的geometry包中引入的Point類型。而且我還添加了兩個方法來操作location： moveTo，用來移動animal；getLocation，用來返回當前的位置。

到目前為止，這還是以Java的方式去get和set一個值。但ActionScript方式會 清晰很多，請看示例：

package com.jherrington.animals
{
　　 import flash.geom.Point;
　　 public class Animal
　　 {
　　　　 public var name:String = "";
　　　　 private var age:int = 0;
　　　　 private var myLocation:Point = new Point(0,0);
　　　　 public function Animal( _name:String, _age:int = 30 )
　　　　 {
　　　　　　 name = _name;
　　　　　　 age = _age;
　　　　 }
　　　　 public function set location( pt:Point ) : void {
　　　　　　 myLocation = pt;
　　　　 }
　　　　 public function get location( ) : Point {
　　　　　　 return myLocation;
　　　　 }
　　 }
}

這裡我使用get和set函數，它們會在客戶代碼獲取或設置成員變量location時 被調用。對於客戶代碼來說，location變量看起來就像是個普通的成員變量。但 事實上，你可以用你喜歡的任何代碼來響應成員變量的設值，以及處理變量的獲 取。

如何來使用它呢？你可以添加一個事件，這個事件會在location發生改變時被 觸發。請看示例代碼：

package com.jherrington.animals
{
　　　 import flash.events.Event;
　　 import flash.events.EventDispatcher;
　　 import flash.geom.Point;
　　 public class Animal extends EventDispatcher
　　 {
　　　　 public var name:String = "";
　　　　 private var age:int = 0;
　　　　 private var myLocation:Point = new Point(0,0);
　　　　 public function Animal( _name:String, _age:int = 30 )
　　　　　　 name = _name;
　　　　　　 age = _age;
　　　　 }
　　　　 public function set location ( pt:Point ) : void {
　　　　　　 myLocation = pt;
　　　　　　 dispatchEvent( new Event( Event.CHANGE ) );
　　　　 }
　　　　 public function get location( ) : Point {
　　　　　　 return myLocation;
　　　　 }
　　 }
}

現在，我指定Animal類是一個事件分發者——也就是說，客戶代碼可以從這個 對象監聽到事件發生。接著，當location改變時，我發出了一個新的事件。

下面就是客戶代碼，它創建了一個animal對象，並開始監聽事件是否發生，然 後就改變了animal的location：

var a:Animal = new Animal();
　　 a.addEventListener(Event.CHANGE, function( event:Event ) : void {
　　　　 trace( "The animal has moved!" );
　　 } );
　　 a.location = new Point( 10, 20 );

這段代碼在animal移動時會記錄一條跟蹤信息。在ActionScript中，你可以定 義任何類型的消息。大多數的類都是EventDispatcher類，你可以為它們的事件添 加監聽器。

接口

就像Java一樣，ActionScript 3語言也支持接口，並使用類來實現它們。下面 的示例中，就是一個我們可以用Animal類來實現的接口：

package com.jherrington.animals
{
　　 import flash.geom.Point;
　　 public interface IAnimal
　　 {
　　　　 function get name() : String;
　　　　 function set name( n:String ) : void;
　　　　 function get location() : Point;
　　　　 function set location( pt:Point ) : void;
　　 }
}

在這個例子中，我為接口定義了兩個可以set和get的成員變量。沒錯，你可以 在ActionScript接口中定義方法和成員變量。是不是很酷？

為了實現這個接口，我對Animal類做了一點修改。請看示例：

package com.jherrington.animals
{
　　 import flash.events.Event;
　　 import flash.events.EventDispatcher;
　　 import flash.geom.Point;
　　 public class Animal extends EventDispatcher implements IAnimal
　　 {
　　　　 private var myName:String = "";
　　　　 public function get name() : String
　　　　 {
　　　　　　 return myName;
　　　　 }
　　　　 public function set name( n:String ) : void
　　　　 {
　　　　　　 myName = n;
　　　　　　 dispatchEvent( new Event( Event.CHANGE ) );
　　　　 }
　　　　 private var myLocation:Point = new Point(0,0);
　　　　 public function set location ( pt:Point ) : void {
　　　　　　 myLocation = pt;
　　　　　　 dispatchEvent( new Event( Event.CHANGE ) );
　　　　 }
　　　　 public function get location( ) : Point {
　　　　　　 return myLocation;
　　　　 }
　　　　 public function Animal( _name:String )
　　　　 {
　　　　　　 name = _name;
　　　　 }
　　 }
}

當然，我也可以為這個類添加特定的變量和方法，或者實現除了IAnimal接口 之外的其他接口。但是和Java一樣，我只能繼承一個基類。

靜態和常量

ActionScript 3支持常量和靜態成員變量，以及靜態方法。常量定義起來很方 便，請看示例：

public const MINIMUM_AGE:int = 0;
　　　　　 public const MAXIMUM_AGE:int = 2000;

常量可以是你期望的任何類型，但它們必須是在編譯時定義。如果你願意，你 也可以把它們定義成受保護的或者是私有的作用域。

為了演示一下靜態方法，我在Animal類中寫了一個工廠方法：

public static function buildAnimal( n:String ) : IAnimal {
　　　　　　 return new Animal( n );
　　　　 }

使用靜態方法的另外一種方式是單例模式。下面就是一個針對Animal類的單例 工廠類：

package com.jherrington.animals
{
　　 public class AnimalFactory
　　 {
　　　　 private static var _factory:AnimalFactory = new AnimalFactory();
　　　　 public static function get instance() : AnimalFactory {
　　　　　　 return _factory;
　　　　 }
　　　　 public function build( n:String ) : Animal {
　　　　　　 return new Animal( n );
　　　　 }
　　 }
}

我使用該單例工廠的instance成員變量來獲得其對象，並調用它：

private var b:Animal = AnimalFactory.instance.build( "Russell" );

這句代碼使用單例工廠對象創建了一個新的名叫Russell的animal對象。

繼承

為了演示繼承，我寫了三個接口和類。第一個是之前的IAnimal接口，第二個 是Animal類，第三個是名叫Dog的繼承類，它覆寫了一個方法。

接口IAnimal定義如下：

public interface IAnimal
　　 {
　　　　 function get name() : String;
　　　　 function set name( n:String ) : void;
　　　　 function move( x:int, y:int ) : void;
　　 }

我對它進行了簡化，這樣它只有一個name成員變量和一個move()方法。第一個 實現這個接口的是Animal類：

public class Animal extends EventDispatcher implements IAnimal
{
　　 private var myName:String = "";
　　 public function get name() : String
　　 {
　　　　 return myName;
　　 }
　　 public function set name( n:String ) : void
　　 {
　　　　 myName = n;
　　　　 dispatchEvent( new Event( Event.CHANGE ) );
　　 }
　　 public function Animal( _name:String )
　　 {
　　　　 name = _name;
　　 }
　　 public virtual　function move( x:int, y:int ) : void
　　 {
　　 }
}

然後，Dog類在Animal類的基礎上構建起來，它具有自己的構造函數，並覆寫 了move()方法：

public class Dog extends Animal
{
　　 public function Dog(_name:String)
　　 {
　　　　 super(_name);
　　 }
　　 public override function move( x:int, y:int ) : void
　　 {
　　　　 trace( 'Moving to '+x+', '+y );
　　 }
}

這看起來非常像Java代碼，所以你會感覺到用ActionScript來實現自己的面向 對象設計會非常輕松。

操作符和條件語句

ActionScript中的操作符和你在Java中看到的完全一樣。類似地，算術和布爾 操作符也是一樣的：

var a:int = 5;
　　 var b:int = 6;
　　 var c:int = a * b;
　　 c *= 10;
　　 var d:Boolean = ( c > 10 );
　　 var e:int = d ? 10 : 20;

這些實例演示了一些不同的操作符。在這些示例中，ActionScript和Java的唯 一不同在於定義變量的語法不一樣。

跟操作符一樣，條件語句也是完全一樣的，請看示例：

if ( a > 10 ) {
　　　　 trace( 'low' );
　　 }
　　 else if ( a > 20 ) {
　　　　 trace( 'high' );
　　 }
　　 else {
　　　　 threw new Exception( "Strange value" );
　　 }

這裡演示了條件語句的語法，以及如何拋出異常。異常處理和Java中的完全一 樣。你可以定義自己的異常類型，或者直接使用標准的Exception類。

下面是try，catch和finally語法的使用：

try
　　 {
　　　　 location = new Point( -10, 10 );
　　 }
　　 catch( Exception e )
　　 {
　　　　 trace( e.toString() );
　　 }
　　 finally
　　 {
　　　　 location = null;
　　 }

這段代碼試圖設置location，並在錯誤發生時跟蹤錯誤信息。不管哪種情況， 最終，location都會被設為null。

迭代

ActionScript 3沒有強類型的容器類，但數組和哈希表使用起來還是非常容易 的。這裡是一個使用for循環來迭代一個數組的例子：

var values:Array = new [ 1, 2, 5 ];
　　 for( var i:int = 0; i < values.length; i++ )
　　　　 trace( values[i] );

但這並不是你在ActionScript中迭代數組應該使用的方式。最好的方式是使用 for each語法，請看示例：

var values:Array = new [ 1, 2, 5 ];
　　 for each ( var i:int in values )
　　　　 trace( i );

這段代碼迭代訪問數組中的每個元素，並把i的值設置為每個元素的值。

要創建一個哈希表，你可以使用ActionScript中基本的Object類型：

var params:Object = { first:'Jack', last:'Herrington' };
　　 for( var key:String in params )
　　　　 trace( key+' = '+params[key] );

ActionScript起源於JavaScript意味著基礎對象類型是基於插槽（slots- based）的容器，這樣你可以輕而易舉地把它作為哈希表來使用。

正則表達式

正則表達式是ActionScript中的基礎語法。比如下面這段代碼：

if ( name.search( /jack/i ) )
　　 {
　　　　 trace('hello jack');
　　 }

是對一個字符串的簡單檢查。

這段代碼是使用正則表達式來執行分割操作：

var values:String = "1,2,3";
　　 for each( var val:String in values.split(/,/) ) {
　　　　 trace( val );
　　 }

你是否應該把正則表達式嵌在自己的核心代碼裡面，是值得商榷的。Java的架 構師們顯然認為這些表達式應該留在一個外部的庫中。但我認為，它們非常有用 ，所以它們應該像在ActionScript中這樣被集成。

E4X

XML應用得很廣泛，以至於ActionScript直接把它構建在語言的語法裡面以示 支持。如果你是個XML愛好者，你會非常喜歡這個的。請看示例：

var myData:XML = <names>
　　 <name>Jack</name>
　　 <name>Oso</name>
　　 <name>Sadie</name>
</names>;
　　 for each ( var name:XML in myData..name ) {
　　　　 trace( name.toString() );
}

這段代碼定義了一個XML文檔，然後對它進行搜索並打印出所有的標簽

下面這段代碼也是獲取<name> 標簽，但只獲取那些type是dog的標簽。

var myData:XML = <names>
　　 <name type="person">Jack</name>
　　 <name type="dog">Oso</name>
　　 <name type="dog">Sadie</name>
</names>;
　　 for each ( var name:XML in myData..name.(@type='dog') ) {
　　　　 trace( name.toString() );
}

@語法有點類似於XPath和XSLT。它用來指定我們要查看的是屬性而不是XML元 素本身。

E4X是對這門語言的夢幻增強。它把XML解析從繁瑣變成了輕松愉快的事情。 Web services甚至也可以以E4X的格式返回以便於解析。

總結

Adobe對於ActionScript做了一些非凡的改進。它是一門比人們想象的成熟得 多的語言。我認為你會最終發現Adobe所做的，就是吸取了Java的得失教訓，並把 它們合並進ActionScript 3語言的開發中。你會很樂意看到最後的結果。