簡單的改.mdb為.asp就能防下載那是鬼話,沒有打過補丁的*.mdb文件是可以下載的。
打過本補丁之後就可以了.就是在.mdb文件裡加入<%<%字段
在你的數據中多了一個名為‘undownload’的表。
如果你的數據庫的擴展名為.mdb，請把擴展名改為.asp才能發揮作用。
<%
Option Explicit
Dim db, oConn, sConnStr, oRs, sSql
db = Request.QueryString("db")
If db = "" Then
Response.Write("請在本文件的URL後台加上?db=(數據庫名稱)")
Response.End()
' db = "db.mdb" '這裡改成您的數據庫地址
End If
Set oConn = Server.CreateObject("Adodb.Connection")
sConnStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(db)
oConn.Open sConnStr
Set oRs = oConn.OpenSchema(20)
oRs.MoveFirst
Do Until oRs.EOF
If oRs("TABLE_TYPE") = "TABLE" Then
If oRs("TABLE_NAME") = "NOTDOWNLOAD" Then
oConn.Execute("Drop TABLE NOTDOWNLOAD")
Exit Do
End If
End If
oRs.MoveNext
Loop
oConn.Execute("Create TABLE NOTDOWNLOAD(NOTDOWN OLEOBJECT)")
Set oRs = Server.CreateObject("ADODB.RECORDSET")
sSql = "Select * FROM NOTDOWNLOAD"
oRs.Open sSql, oConn, 1, 3
oRs.Addnew
oRs("notdown").appendchunk(chrB(Asc("<")) & chrB(Asc("%")) & chrB(Asc("<")) & chrB(Asc("%")))
oRs.Update
oRs.Close
Set oRs = Nothing
oConn.Close
Set oConn = Nothing
Response.Write("MDB數據庫擴展名改為ASP防下載補丁完成,請將.mdb文件改為.asp文件")
%>
