以下函數采用FSO對象，文件位置在FSO.ASP。FSO對象的文件編碼屬性只有三種，系統默認，Unicode，ASCII，並沒有我們要的utf-8，所以一般中文系統上使用FSO對象生成的文件都是gb2312網頁編碼格式，無法生成UTF-8編碼，因此，英文等拉丁語系和中文可以正常顯示，但象俄語等非拉丁語系，頁面就會出現亂碼。
復制代碼 代碼如下:
function createfile(sfilename,scontent)
set fso=server.CreateObject("scripting.filesystemobject")
'set f1=fso.opentextfile(sfilename,2,true,-1) 'append=8 only write=2 Unicode編碼=-1
set f1=fso.opentextfile(sfilename,2,true)
f1.write(scontent)
f1.close
set fso=nothing
end function
選擇用ADODB.STREAM對象來替代FSO對象，因為STREAM類有LOADFROMFILE和SAVETOFILE方法，並且有一個至關重要的屬性CHARSET，這是FSO沒有的。以下函數采用用Adodb.Stream編寫，成功生成UTF-8網頁文件。
復制代碼 代碼如下:
function createfile(sfilename,scontent)
Set objStream = Server.CreateObject("ADODB.Stream")
With objStream
.Open
.Charset = "utf-8"
.Position = objStream.Size
.WriteText=scontent
.SaveToFile sfilename,2
.Close
End With
Set objStream = Nothing
end function
對於采用FSO的程序，只要把這個函數修改一下， 函數名稱不變，就可以正常運行， 比較省事方便。
如果采用模板生成文件， 還需要把模板文件用UTF-8編碼讀進來，否則，後台發布正確文件編碼，但模板文件讀進來是用FSO的GB2312編碼，模板頁面的俄語等非拉丁語系，就會出現亂碼。函數修改如下：
原來采用的FSO 的READFILE函數
復制代碼 代碼如下:
function readfile(sfilename)
Set fso=server.CreateObject("scripting.filesystemobject")
Set f = fso.OpenTextFile(sfilename, 1, true)
if not f.AtEndOfStream then readfile = f.readAll
Set f=nothing
Set fso=nothing
end function
替換采用的ADODB.STREAM 的READFILE函數
注意根據實際需要，去掉或保留Function readfile (sfilename,charset)charset參數charset。
復制代碼 代碼如下:
Function readfile (sfilename)
Dim f
Set stm=server.CreateObject("adodb.stream")
stm.Type=2 '以本模式讀取
stm.mode=3
stm.charset="utf-8"
stm.open
stm.loadfromfile sfilename
f=stm.readtext
stm.Close
Set stm=Nothing
readfile=f
End Function
關於文件編碼和網頁編碼， 請參考“字符集Charset和文件編碼Encoding的區別詳解”。
其他樣例程序
復制代碼 代碼如下:
'-------------------------------------------------
'函數名稱:ReadTextFile
'作用:利用AdoDb.Stream對象來讀取UTF-8格式的文本文件
'----------------------------------------------------
Function ReadFromTextFile (FileUrl,CharSet)
Dim str
Set stm=server.CreateObject("adodb.stream")
stm.Type=2 '以本模式讀取
stm.mode=3
stm.charset=CharSet
stm.open
stm.loadfromfile server.MapPath(FileUrl)
str=stm.readtext
stm.Close
Set stm=nothing
ReadFromTextFile=str
End Function
'-------------------------------------------------
'函數名稱:WriteToTextFile
'作用:利用AdoDb.Stream對象來寫入UTF-8格式的文本文件
'----------------------------------------------------
Sub WriteToTextFile (FileUrl,byval Str,CharSet)
Set stm=Server.CreateObject("adodb.stream")
stm.Type=2 '以本模式讀取
stm.mode=3
stm.charset=CharSet
stm.open
stm.WriteText str
stm.SaveToFile server.MapPath(FileUrl),2
stm.flush
stm.Close
Set stm=Nothing
End Sub
其中， 這一行要注意路徑問題，stm.SaveToFile server.MapPath(FileUrl),2
