http://www.im286.com/viewthread.php?tid=1550010&extra=page%3D1
其實這個問題落伍談了n次了
其中care4也說了兩次所以如果你有問題最好先搜索一下 說不定問題早有人解決了
http://www.im286.com/viewthread. ... ;highlight=%2Bcare4
http://www.im286.com/viewthread. ... ;highlight=%2Bcare4
care4的代碼有一個小缺點 就是需要組件。
第一個是.net組件 二不是 但用組件始終不太方便有沒有asp直接獲取的方式呢
答案是有的
我寫的一個vb簡單的winsock獲取的代碼
http://www.im286.com/viewthread. ... t=Response.redirect
當時我說用asp好像不能獲得，那是當時沒有去csdn混去，現在搞定了
首先我們要了解為什麼xmlhttp組件無法獲得這樣的跳轉真實地址
用Response.Redirect跳轉，PHP裡面是Header("Location",$URL);
這兩種方式都是一樣的原理，就是在輸出的HTTP頭裡面加上一個Location字段
同時把返回的HTTP狀態值設為302，浏覽器就會認為當前請求的頁面已經
被移動到Location指定的路徑
那麼為什麼xmlhttp無法獲得呢？
原因很簡單
XMLHTTP組件在處理包含Location頭的302消息時太智能了，直接給跳轉到最後的頁面，也就是說～我們看不到中間的過程！比爾自作聰明阿 ！
不過還好MSXML4裡面提供了一個可用的新的組件：WinHttp.WinHttpRequest.5.1，這個也是MSXML4 XMLHTTP組件的核心。 WinHttp.WinHttpRequest有一個十分關鍵的屬性：Option，這個屬性的第六個索引就是指示是否自動跳轉，然後就可以輕松的使用XMLHTTP組件的getResponseHeader和getAllResponseHeaders方法來獲取返回的HTTP頭信息了。
好接下來就看代碼了
Dim oHttp
Set oHttp=Server.CreateObject("WinHttp.WinHttpRequest.5.1"
oHttp.Option(6)=0 '禁止自動Redirect，最關鍵的 剩下的就簡單讀取數據都估計大家都會
oHttp.SetTimeouts 5000,5000,30000,5000 '設置超時～和ServerXMLHTTP組件一樣
oHttp.Open "GET",sUrl,False '以同步模式打開URL
If oHttp.Status<>200 And oHttp.Status<>302 Then
'oHttp.Status對應返回的HTTP狀態，如果是200，表示這個就是最終頁面，沒有Location跳轉
'如果是302，表示當前請求的URL已經被移動，需要根據HTTP頭來跳轉
'對於其他數值的狀態，基本上我們不要處理，但是你要處理也可以比如 440或者別的狀態你自己處理就可以了！
Else
'在這裡對返回的HTTP頭和文檔內容進行處理
End If
好了比較完整的代碼比較長
我傳了個到空間上自己看去
http://test.aymtv.com/url.asp
默認的輸入欄裡的代碼是crsky的一個下載地址你可以測試一下就知道了
點查看源代碼就可以看見這個asp文件的源代碼！
一切搞定 over 繼續去csdn混分去了
<%
Public Function Bytes2BSTR(v)
Dim r,i,t,n : r = ""
For i = 1 To LenB(v)
t = AscB(MidB(v,i,1))
If t < &H80 Then
r = r & Chr(t)
Else
n = AscB(MidB(v,i+1,1))
r = r & Chr(CLng(t) * &H100 + CInt(n))
i = i + 1
End If
Next
Bytes2BSTR = r
End Function
'==========================================================================================
If Request.QueryString="ViewSource" Then
Dim oFso : Set oFso=Server.CreateObject("Scripting.FileSystemObject")
Dim oFil : Set oFil=oFso.OpenTextFile(Server.MapPath("URL.Asp"))
Dim sTxt : sTxt=oFil.ReadAll()
oFil.Close : Set oFil=Nothing : Set oFso=Nothing
Response.ContentType="text/plain"
Response.Write sTxt
Response.ENd
End If
%><?xml version="1.0" encoding="gb2312" standalone="yes"?>
<!doctype html public "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns:v="http://www.eglic.com/">
<head>
<title></title>
<meta name="Generator" content="EditPlus" />
<meta name="Author" content="eglic" />
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<meta name="CharSet" content="GB2312" />
<link rel="stylesheet" type="text/css" href="/styles/default.css" />
<style type="text/css">
@media all{
}
</style>
<script language="javascript" src="/scripts/default.js"></script>
<script language="javascript" src="/scripts/xml.js"></script>
<script language="javascript">//<!--
//--></script>
</head>
<body>
<form action="" method="POST">
要檢測的URL：<input type="text" name="URL" size="50" value="<%
If Request.Form("URL")<>"" THen
Response.Write Trim(Request.Form("URL"))
Else
Response.Write "http://www.crsky.com/view_down.asp?downd_id=8&downd=0&ID=20780&down=yes"
End If
%>" />
<input type="submit" value="提交" />
<input type="button" value="查看源代碼" onclick="JavaScript:window.open('<%=URLSelf%>?ViewSource');" />
</form>
<%
Public Function GetAbsoluteURL(sUrl,ByRef iStep)
Dim bUrl,bDat
If iStep>15 Then
Err.Raise vbObejctError,"遞歸錯誤","遞歸嵌套超過15層可能會引起程序崩潰"
End If
If InStr(sUrl,"://")<=0 Then sUrl="http://" & sUrl
If InStr(sUrl,"?")>0 THen
Dim tmpUrl : tmpUrl=split(sUrl,"?")
bUrl=tmpUrl(0)
bDat=tmpUrl(1)
Else
bUrl=sUrl
bDat=""
End If
Response.Write "<p style=""border:solid 1px silver;border-top:solid 2px red;padding:5px;margin:2px;"">"
Response.Write "第 " & iStep & " 步："
Response.Write "正在准備獲取 " & bUrl & "<br />"
iStep=iStep+1
if bDat<>"" Then Response.Write " >>參數： " & bDat & "<br />"
Dim oHttp : Set oHttp=Server.CreateObject("WinHttp.WinHttpRequest.5.1")
oHttp.Option(6)=0 '禁止自動Redirect，最關鍵的
'oHttp.Option()
oHttp.SetTimeouts 5000,5000,30000,5000
oHttp.Open "GET",sUrl,False
On Error Resume Next
oHttp.Send bDat
If Err.Number<>0 Then
Response.Write "<font color=""red"">發生錯誤：" & Err.Description & "</font><br />"
Err.Clear
GetAbsoluteURL=""
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
On Error Goto 0
Response.Write " >>HTTP 狀態：" & oHttp.Status & "<br />"
If oHttp.Status<>200 And oHttp.Status<>302 Then
Response.Write "<font color=""red"">HTTP錯誤：" & oHttp.StatusText & "</font><br />"
Err.Clear
GetAbsoluteURL=""
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
Dim sLoca
On Error Resume Next
sLoca=oHttp.getResponseHeader("Location")
If Err.Number<>0 Then
Err.Clear
sLoca=""
End If
On Error Goto 0
If sLoca = "" Then
Response.Write " >>Content-Type:" & oHttp.getResponseHeader("Content-Type") & "<br />"
Response.Write " >>Content-Length:"
On Error Resume Next
Response.Write oHttp.getResponseHeader("Content-Length")
If Err.Number<>0 THen Err.Clear
On Error Goto 0
Response.Write "<br />"
Response.Write " >>沒有返回Location頭，繼續分析頁面<br />"
If oHttp.getResponseHeader("Content-Type")="text/html" Then '是HTML類型才繼續處理
Dim sBody : sBody=Bytes2BStr(oHttp.responseBody)
Dim r : Set r=new Regexp
r.MultiLine=True
r.Global=True
r.IgnoreCase=True
r.Pattern="<meta.+http\-equiv\=\""refresh\"".+content=\""[^\;]+;url\=([^\""\s\>]*).*$"
If r.Test(sBody) Then
Response.Write " >>發現 Refresh 地址<br />"
Dim m : Set m=r.Execute(sBody)
Dim tRefUrl : tRefUrl=r.Replace(m(0).Value,"$1")
If InStr(tRefUrl,"://")<=0 Then '沒有指定協議，按當前URL的位置重新設置
Dim ind1 : ind1=InstrRev(sUrl,"/")
sUrl=Left(sUrl,ind1)
tRefUrl=sUrl & tRefUrl
End If
Set r=Nothing
Set oHttp=Nothing
Response.Write " >>准備分析 <u>" & tRefUrl & "</u><br />"
Response.Write "</p>"
GetAbsoluteURL=GetAbsoluteURL(tRefUrl,iStep)
Exit Function
Else
Response.Write " >>沒發現 Refresh Meta 轉向，這可能就是最終的URL<br />"
GetAbsoluteURL=sUrl
Set r=Nothing
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
Else
GetAbsoluteURL=sUrl
Set oHttp=Nothing
Response.Write "</p>"
Exit Function
End If
'這裡要繼續分析網頁內容
Else
Response.Write " >>Content-Type:" & oHttp.getResponseHeader("Content-Type") & "<br />"
Response.Write " >>Content-Length:"
On Error Resume Next
Response.Write oHttp.getResponseHeader("Content-Length")
If Err.Number<>0 THen Err.Clear
On Error Goto 0
Response.Write "<br />"
Response.Write " >><u>Location : " & sLoca& "</u><br />"
Response.Write "</p>"
'這裡要生成新的URL
If InStr(sLoca,"://")<=0 Then
'沒有指定協議，按當前URL的位置重新設置
Dim ind : ind=InstrRev(sUrl,"/")
sUrl=Left(sUrl,ind)
sLoca=sUrl & sLoca
End If
GetAbsoluteURL=GetAbsoluteURL(sLoca,iStep)
End If
End Function
If Request.Form("URL")<>"" THen
Dim iStep : iStep=1
Dim sAbs : sAbs=GetAbsoluteURL(Trim(Request.Form("URL")),iStep)
Response.Write "<strong style=""color:white;background-color:red;font-size:15px;padding:3px;margin:10px;"">最終結果是：" & sAbs & "</strong>"
End If
%>
<script src="/T/mystat.asp?siteid=1"></script>
</body>
</html>
