內容為
表名：zai
字段為
１.ip
2.time
建立一個文件為index.asp
然後就如下程序！
<%
'===================================================================================================
'
'******************** 冰翎在線人數統計程序 V2.0 ******************************
'
' 本站程序由 『冰翎工作室』--冰淇淋劍客 獨立制作！請尊重本人的勞動成果
'
' 『冰翎工作室』─━╃→用實力打造個性
'
'* 作者:冰淇淋劍客
'* 網站:http://www.blbcn.com
'* 電子郵件:[email protected]
'* QQ:68156987
'* 住址：江蘇無錫
'******************************************************************************
'
' 版權所有·抄襲挪用必究
'
'===================================================================================================
'---------定義變量
dim rs
dim ip
dim timeout
dim x
dim conn
dim dbpath
'---------定義變量結束
'---------建議數據庫鏈接
set conn=server.createobject("adodb.connection")
DBPath = Server.MapPath("zai.mdb")
conn.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & DBPath
'---------建立數據庫鏈接完成
'---------新建數據庫RS對象
set rs = server.createobject("adodb.recordset")
'---------建立數據庫RS對象完成
'---------讀取客戶端IP地址
ip = Request.ServerVariables("HTTP_X_FORWARDED_FOR") '若是對方使用的是代理服務器上網的話,用Request.ServerVariables("HTTP_X_FORWARDED_FOR")可以得到對方的真實IP,若對方不是通過代理服務器上網的話,則IP的值為空
If ip = "" Then ip = Request.ServerVariables("REMOTE_ADDR") '如果IP的值為空,則得到他的本地客戶端地址
'---------IP讀取完畢
'---------讀出數據庫內近20分鐘所加入的新內容數,group by ip-表IP值相同的記作1
sql="select ip from zai where time >= dateadd('n',-20,now()) group by ip"
rs.Open sql,conn,1,1
zai=rs.RecordCount
rs.Close
'---------得到在線人數值
'---------查看數據庫中是否已經有相同的值,沒有則 x="yes"有則x="no"
sql="select ip from zai where ip='" & ip & "'"
rs.Open sql,conn,1,1
if rs.eof and rs.bof then
x="yes"
else
x="no"
end if
rs.close
'--------判斷完畢
'--------如果數據庫中沒有相同的值則加入一個新值
if x="yes" then' 如果沒有這個ＩＰ則增加一條記錄
sql="select top 1 * from zai"
rs.Open sql,conn,1,3
rs.AddNew
rs("ip")=ip
rs("time")=now()
rs.update
rs.close
else '如果有這個ＩＰ則把時間改為現在的時間
sql="select * from zai where ip='" & ip & "'"
rs.Open sql,conn,1,3
rs("time")=now()
rs.update
rs.close
end if
'--------判斷加入完畢
'--------刪除20分鐘以前所加入的值
timeout = dateadd("n", -20, now())
sql="delete * from zai where time < #" & timeout & "#"
conn.Execute sql
'--------刪除完畢
'--------關閉數據對象
set rs=nothing
conn.Close
set conn=nothing
%>
document.write("共<%=zai%>人在線")
ＯＫ！
完成了！
