〓簡介〓
有點常識的人都知道本身用asp做這種功能顯然有些牽強，因為他不像qq，msn或irc 聊天室那樣是即時通訊，他都是靠刷新網頁更改最後活動時間來獲取用戶是否在線的，所以您不要指望下面這片教程有多完美，我也只是把我的思維模式記錄下來，有啥不對的地方還請高手們多多指教！
--------------------------------------------------------------------------------
〓正文〓
首先我先向大家介紹一下我實現這個效果的思路，如果你看過我的思路後就能理解完全沒必要將這篇東西看完……
實現這個功能我只能想到兩種方式來實現：
1。數據庫+asp
做起來可能會復雜些，但是適合有大量登陸用戶的系統裡。
2。application
用application對象：如果你做的是大型社區，你可能要為每個登陸id生成一個appliaction，這樣做雖然程序上設計會簡單些但登陸用戶過多及其耗費服務器資源，我這裡決不提倡，因為appliaction對象在用戶登陸時生成很容易但是要做到真正的隨著用戶退出系統完全釋放掉，到目前我還沒看到更好的方法~
因此還是讓我們來看看用數據庫+asp是如何實現同一個帳號不能同時登陸的問題的吧！
首先問用戶建立數據庫這裡我們用access新建一個onlyNet118.mdb
數據表1： users 存放用戶注冊資料
下設數據表：uID（自動編號） userName（字符型） userPass（字符型）
數據表2： onlyLogin 存放用戶臨時登陸信息
下設數據表： OLname（字符型） OLtime（日期型） OLip（字符型）
數據庫建好後我們直接向users表中手動添加數據 userName表添加Net118，userPass表裡添加111，為了能突出我們本文討論的重點，去掉不必要的廢話，所以密碼也不要加密了，用戶名也自己添加~哈哈~
好了，現在數據庫裡面有用戶數據庫，下面我們來做用戶登陸界面，復制下面代碼存成onlyLogin.asp文件。
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>Net118.COM禁止同一賬號不同地區同時登陸</title>
</head>
<body>
<form name="form1" method="post" action="loginPost.asp">
用戶名：<input name="userName" type="text" id="userName" size="15" maxlength="5">
密碼：<input name="userPass" type="password" id="userPass" size="15" maxlength="15">
<input type="submit" name="Submit" value="Login">
</form>
</body>
</html>
完成後在新建一個loginCONN.asp文件復制下面的代碼保存！是連接數據庫的，這個我就不多解釋了……
<%
Dim CONN_Net118
Dim Conn_T
Dim mmdd
mmdd="onlyNet118.mdb"
Set CONN_Net118 = Server.CreateObject("ADODB.Connection")
Conn_T="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&mmdd&"")
on error resume next
CONN_Net118.Open Conn_T
%>
下面我們做一個loginPost.asp文件也存在這個目錄下，這個比較關鍵，仔細看下面的代碼：
<!--#include file="loginCONN.asp" -->
<%
'刪除maxTime時間內部活動的用戶,maxTime 在loginCONN.asp文件裡面已經定義好了
Conn_Net118.Execute("Delete From onlyLogin where DATEDIFF('s',OLtime, now()) > "& maxTime & "")
'================================================================
Dim rs, ts, txt, sql, userName, userPass
if Request.Form("Submit")="Login" then
userName=Request.Form("userName")'獲取表單用戶登陸名
userPass=Request.Form("userPass")'獲取表單用戶登陸密碼
'由於我們這裡討論的不是安全問題所以用戶密碼都沒有加密
Set rs = Server.CreateObject("ADODB.RECORDSET")
sql="SELECT * FROM users where userName = ' "& userName & "' and userPass = ' "& userPass & "'"
rs.Open sql, CONN_Net118,1,1
IF not rs.eof then
Call isOK(userName) ' 用戶名密碼正確調用次過程，isOK將會在下面的程序中定制。
else
Response.Write("<a href=javascript:history.go(-1)>用戶名或密碼錯誤</a>")
Response.End()
end if
rs.Close
Set rs=Nothing
end if
Sub isOK(userName)
Dim Olip ' 數據庫中當前登陸用戶名保存的ip
Dim Oltime ' 數據庫中當前登陸用戶名保存的最後刷新網頁的時間，是計算用戶是否在線的重要數據。
Dim OLip1 ' 記錄當前用戶登陸ip，用來區分是否為同一用戶的標示
OLip1=Request.ServerVariables("REMOTE_ADDR")'取得提交登陸信息用戶的IP
Set ts=Conn_Net118.execute("Select * FROM onlyLogin WHERE OLname='"& userName & "'")
if not ts.eof then ' 查詢數據庫是否有此用戶的登陸過的信息
OLtime=ts("OLtime")
OLip=ts("OLip")
if OLip1<>OLip and DateDiff("s",OLtime,now()) < maxTime then
'上句判斷如果提交登陸用戶ip不是數據庫中最後紀錄的用戶ip並且
'用戶的最後活動時間和當前時間相隔並沒超過規定的秒數則確認此用戶當前在線
Response.Write "<a href=javascript:history.go(-1)>此用戶目前在線，你無法從其他地方登陸此賬號！</a>"
Response.End()
else
'否則的話判定登陸成功付值給session
Session("lgName")=userName
Session("lgPass")=userPass
Response.Redirect "loginOK.asp"
Response.End
end if
else
'如果數據庫沒有次登陸用戶紀錄則執行下面的語句
Dim ls
Set ls=Server.CreateObject("ADODB.RECORDSET")
ls.Open"Select * From onlyLogin",CONN_Net118,2,2
ls.ADDNEW
ls("OLname")=userName
ls("OLip")=OLip1
ls("OLtime")=NOW()
ls.UPDATE
ls.Close
Set ls=Nothing
'判定登陸成功付值給session
Session("lgName")=userName
Session("lgPass")=userPass
Response.Redirect "loginOK.asp"
Response.End
end if
End Sub %>
如果你看得懂asp文件一看便知道登陸成功後葉面會跳轉到loginOK.asp下面我們馬上看看這個葉面的代碼吧
<style type="text/css">
<!--
body {background-color: #FF9900;}
-->
</style>
<% IF Session("lgName")<>"" then %>
您登陸成功了！！！下面是潛入網頁內的iframe為的是在規定的時間刷新網頁向服務器報告你是否在線
為了便於區分，frame網頁我們采用了白色作為底色
<iframe border=0 name=new_date marginwidth=0 framespacing=0 marginheight=0 src="loginFrame.asp"
frameborder=0 noResize width=100 scrolling=no height=30 vspale="0"></iframe>
<% else %>
您沒有登陸哈 歡迎光臨站長資訊網：http://www.Net118.com
<% end if %>
如果你是細心之人馬上就知道下面我麼要做的是loginFrame.asp
<!--#include file="loginCONN.ASP" -->
<% CONN_Net118.Execute("Update onlyLogin Set OLtime='"& NOW() & "' where OLname = ' "& Session("lgName") & "'") %>
<html><head><meta http-equiv="refresh" content="<%=(maxTime-5)%>; url=""></head></html>
好了到此為止我們的程序就完成了，這個程序的關鍵就是判定用戶是否在線，而我也是無可奈何的是用了FRAME把定時刷新確定用戶在線的關鍵性葉面嵌套在主程序的葉面裡，實際的操作中你可以把那個iframe的寬和高改為0讓一般用戶看不到，或者讓主程序的網頁底色和那個嵌套進來的定時刷新的網頁一樣就ok了。
前不久在討論區看到有人說用session和cookies之類的東西也能判定，這顯然是不可能的呀，因為他們生成的對象都是對自己起作用的，其數據內容根本無法和其他用戶共用。appliaction應該是實現這一目的的另一種方法，但是我一想到如果同是有很多用戶登陸要為每個用戶生成至少一個到三個appliaction對象就放棄了這個念頭，因為那樣我們原本可憐的服務器一定會被拖垮~
