access新手來看：如何重復上一條記錄？

手來看：如何重復上一條記錄？

問題：

如何重復上一條記錄？

有一個窗體,上面有多個文本框和組合框,因為目錄這筆資料與下一筆資料大部門都是一樣的,能不能利用copy功能把上一筆的資料復制到下一筆的相對應的文本框和組合框內.最好是做成按鈕式,即一個復制按鈕和一個粘貼按鈕。

方法一：

很多軟件裡面都有這個功能啊？

原理非常簡單。

只要添加一個command BUTTON 就可以了。

添加記錄的代碼相信大家都知道了。

　

Private Sub Command16_Click()
On Error GoTo Err_Command16_Click

    DoCmd.GoToRecord , , acNewRec

exit_command16_click:
    Exit Sub

err_command16_click:
    MsgBox Err.Description
    Resume Exit_Command16_Click
    
End Sub

我們更改一下即可，比如說現在有一個文本框，當然了，實際情況你可以再加代碼，或者干脆用CONTROLS循環來做。

Private Sub Command16_Click()
On Error GoTo Err_Command16_Click

    dim strTemp as string
    strTemp=TextBox1.value
    '原理很簡單，先將控件值賦值給變量
    '然後在添加記錄後再將該變量值賦值給控件
    DoCmd.GoToRecord , , acNewRec

    TextBox1.value=strTemp
Exit_Command16_Click:
    Exit Sub

err_command16_click:
    MsgBox Err.Description
    Resume Exit_Command16_Click
    
End Sub

另外 Ctrl+'(單引號)可以復制上一條記錄同一字段內容。

方法二：　

用controls循環的代碼如下：

Private Sub AutoWriteRecord()
'自適應
On Error GoTo Err_AutoWriteRecord
    Dim D                   '創建一個變量
    Set D = CreateObject("Scripting.Dictionary")
    
    Dim i As Long
    For i = 0 To Me.Controls.Count - 1
        If Me.Controls(i).ControlType = acTextBox _
        Or Me.Controls(i).ControlType = acComboBox _
        Or Me.Controls(i).ControlType = acListBox _
        Or Me.Controls(i).ControlType = acCheckBox _
        Or Me.Controls(i).ControlType = acOptionButton Then
            If Me.Controls(i).Name <> "編號" Then
            '自動編號字段不可寫，所以除外，可以用on error resume next 忽略
                D.Add Me.Controls(i).Name, Me.Controls(i).Value
            End If
        End If
    Next i
    '原理很簡單，先將控件值賦值給變量
    '然後在添加記錄後再將該變量值賦值給控件
    DoCmd.GoToRecord , , acNewRec

    Dim K
    K = D.keys
    
    For i = 0 To D.Count - 1
        Me.Controls(K(i)).Value = D(K(i))
    Next i
    
    Set D = Nothing
    
Exit_AutoWriteRecord:
    Exit Sub

err_autowriterecord:
    MsgBox Err.Description
    Resume Exit_AutoWriteRecord
    
End Sub

　

Private Sub AutoWriteRecord_1(strControlName As String)
'人工定義控件名
On Error GoTo Err_AutoWriteRecord
    Dim D                   '創建一個變量
    Set D = CreateObject("Scripting.Dictionary")
    
    Dim strSName() As String
    strSName = Split(strControlName, ";")
  
    Dim i As Long
    For i = 0 To UBound(strSName) - 1
        D.Add strSName(i), Me.Controls(strSName(i)).Value
    Next i
    '原理很簡單，先將控件值賦值給變量
    '然後在添加記錄後再將該變量值賦值給控件
    DoCmd.GoToRecord , , acNewRec

    For i = 0 To UBound(strSName) - 1
        Me.Controls(strSName(i)).Value = D(strSName(i))
    Next i
    Set D = Nothing
    
Exit_AutoWriteRecord:
    Exit Sub

err_autowriterecord:
    MsgBox Err.Description
    Resume Exit_AutoWriteRecord
    
End Sub

測試：

Private Sub Command16_Click()
    'AutoWriteRecord
    AutoWriteRecord_1 "字段1;字段2;字段4;"
End Sub