針對這種問題，該如何處理呢？對於目前流行的三層結構（Browser/Application/Server）開發來講，這個問題可以通過設置應用服務器端的連接共享池（shared pool）來避免。但對於傳統的兩層結構（ClIEnt/Server）應用，就必須由我們人為干預來避免這種資源浪費情況。具體可以通過一個後台任務來監控系統中的所有進程，對於那些空閒超過一定時間的進程采取一定的特殊處理措施，如在客戶端提示用戶連接時間太長，如果沒有後續操作系統將自動殺掉該連接或者直接將該空閒連接殺掉。下面就來具體討論如何在Oracle 8x環境下實現用戶進程的自動監控及其對對超過一定空閒時間連接的處理辦法。
一、識別系統中超過一定空閒時間的連接
要實現後台任務自動對超過一定時間空閒連接的處理，首先第一步工作就是要從所有與數據庫服務器的連接中識別出那些連接需要處理，也就是需要獲得與服務器連接的每個用戶的登陸時間及其最後一次操作後的空閒時間。在Oracle系統中，有一個動態性能視圖v$session，該視圖保存著系統當前連接的各種動態信息。其中，有兩個字段LOGON_TIME和 LAST_CALL_ET可以得到上面的兩個答案。
l LOGON_TIME是一個日期型（Date）字段，為用戶登陸時間；
l LAST_CALL_ET是一個數字型（Number）字段，其含義是用戶最後一條語句執行完畢後的時間，單位為秒。每次用戶執行一個新的語句後，該字段復位為0，重新開始記數。我們可以通過該字段來獲得一個連接用戶最後一次操作數據庫後的空閒時間。
下面的SQL查詢語句可以得到與當前數據庫連接的所有用戶的一些基本情況，如用戶名、狀態、連接機器的名稱，操作系統中用戶的名稱，UNIX系統的進程號，在UNIX操作系統級斷開連接的語句，Oracle數據庫系統斷開連接的語句，登陸時間以及最後一次操作到現在的空閒時間等等。
SELECT s.username 用戶名稱, s.status 狀態,s.Machine 機器名稱,
osuser 操作系統用戶名稱,spid UNIX進程號,
'kill -9 '||spid UNIX級斷開連接,
'alter system kill session ' ||''''||s.sid||','||s.serial# || ''';' Oracle級斷開連接,
TO_CHAR (logon_time, 'dd/mm/yyyy hh24:mi:ss') 登陸時間,
last_call_et 空閒時間秒,
TO_CHAR (TRUNC (last_call_et / 3600, 0))||' '||' HRS '||
TO_CHAR (
TRUNC ((last_call_et - TRUNC (last_call_et / 3600, 0) * 3600) / 60, 0)
) ||' MINS' 空閒時間小時分鐘,
module 模塊
FROM v$session s, v$process p
WHERE TYPE = 'USER'
AND p.addr = s.paddr
AND status != 'KILLED'
-- AND SUBSTR (Machine, 1, 19) NOT IN ('機器名')
AND last_call_et > 60 * 60 * 1 -- 空閒時間超過1小時的連接
ORDER BY last_call_et desc;
在上面的查詢中，我們可以通過SUBSTR (Machine, 1, 19) NOT IN ('機器名')這個條件來屏蔽一些機器，這些機器可能需要運行一些耗費很長時間的SQL語句或其他一些特殊情況的機器。屏蔽這些機器的原因就是在後面的後台自動識別及處理任務中對這些機器不作處理。
二、識別及斷開空閒用戶的存儲過程
上面的查詢語句可以得到系統中所有的連接用戶的一些基本情況，但是又如何來實現系統自動判斷空閒超過一定時間的連接並將其自動斷開呢？Oracle系統提供了一種稱之為後台任務（Job）自動處理的機制。我們可以編寫一個後台任務來定時執行，從而判斷是否存在這樣的用戶連接，如果存在，則通過後台任務將其自動斷開。
首先創建一個存儲過程來完成空閒一定時間用戶的識別和斷開工作，然後添加一個後台任務來定時（根據空閒時間長短來確定）執行該過程，即可實現自動斷開系統中空閒超過一定時間用戶的需求。
存儲過程p_monitor見下，其中參數an_nimutes為用戶輸入參數，用來確定識別和斷開多長空閒時間連接的用戶，單位為分鐘，默認為60分鐘，也就是1小時。需要注意一點的是，該存儲過程，需要以sys用戶身份運行。相應，調用該存儲過程的後台任務也需要以SYS身份來添加。
CREATE OR REPLACE PROCEDURE P_MONITOR(
AN_MINUTES NUMBER DEFAULT 60)
/*******************************************
存儲過程用途：識別出系統中超過一定空閒連接時間(
AS_MINUTES)的用戶，並將其kill掉參數:
AN_MINUTES 空閒時間數，單位為分鐘，默認為60分鐘
********************************************/
AS
v_Str VARCHAR2(100);
CURSOR C_users(v_minutes number) IS SELECT s.username,
s.status, s.Machine, 'alter system kill session '
||''''||s.sid||','||s.serial# ||'''' Operates
FROM v$session s, v$process p
WHERE TYPE = 'USER'
AND p.addr = s.paddr
AND status != 'KILLED'
-- AND SUBSTR (Machine, 1, 19) NOT IN ('需要屏蔽不被處理的機器名')
AND last_call_et > v_minutes*60
ORDER BY last_call_et desc;
BEGIN
FOR T_users IN C_users(an_minutes) LOOP
v_Str := T_USERS.OperaTES;
EXECUTE IMMEDIATE v_str;
END LOOP;
END;
/
三、後台任務的定時執行
最後，我們為系統添加一個定時任務，定時調用上面創建的存儲過程，即可完成系統自動識別和處理空閒用戶的工作。
下面是一個實際調用的例子，在sys用戶下，首先添加一個任務，該任務每隔半小時運行一次，每次均調用P_monitor存儲過程，找出系統中空閒時間超過1小時的連接，然後自動斷開。
DECLARE
jobno number;
BEGIN
DBMS_JOB.SUBMIT(
job => jobno,
what => 'p_monitor(60);',
next_date => SYSDATE,
interval => '/*1:Hr*/ sysdate + 30/1440); -- 每半小時運行一次
END;
/
