用SQL腳本讀取Excel中的sheet數量及名稱的方法代碼

復制代碼 代碼如下:
-- Get table (worksheet) or column (field) listings from an excel spreadsheet  

-- 設置變量  
declare @linkedServerName sysname = 'TempExcelSpreadsheet' 
declare @excelFileUrl nvarchar(1000) = 'D:\text.xlsx' 
-- /SET  

-- 刪除鏈接服務（如果它已經存在）  
if exists(select null from sys.servers where name = @linkedServerName) begin 
    exec sp_dropserver @server = @linkedServerName, @droplogins = 'droplogins' 
end 

-- 添加服務對象  
-- ACE 12.0 可以很好地工作為*.xls 和 *.xlsx, 你也可以用 Jet ,但是只能訪問*.xls文件  
exec sp_addlinkedserver  
    @server = @linkedServerName,  
    @srvproduct = 'ACE 12.0',  
    @provider = 'Microsoft.ACE.OLEDB.12.0',  
    @datasrc = @excelFileUrl,  
    @provstr = 'Excel 12.0;HDR=Yes' 

-- 獲取當前用戶  
declare @suser_sname nvarchar(256) = suser_sname()  

-- 添加當前用戶作為登陸這個鏈接服務  
exec sp_addlinkedsrvlogin  
    @rmtsrvname = @linkedServerName,  
    @useself = 'false',  
    @locallogin = @suser_sname,  
    @rmtuser = null,  
    @rmtpassword = null 

-- 返回 sheet 和 各個 sheet中的列  
exec sp_tables_ex @linkedServerName  
exec sp_columns_ex @linkedServerName  

--刪除鏈接服務對象 

if exists(select null from sys.servers where name = @linkedServerName) begin 
    exec sp_dropserver @server = @linkedServerName, @droplogins = 'droplogins' 
end