程式師世界 >> 數據庫知識 >> 其他數據庫知識 >> MSSQL >> 關於從新組織和從新生成索引sp_RefreshIndex的引見

關於從新組織和從新生成索引sp_RefreshIndex的引見

編輯：MSSQL

關於從新組織和從新生成索引sp_RefreshIndex的引見。本站提示廣大學習愛好者：（關於從新組織和從新生成索引sp_RefreshIndex的引見）文章只能為提供參考，不一定能成為您想要的結果。以下是關於從新組織和從新生成索引sp_RefreshIndex的引見正文

開端：

--------------------------------------------------------------------------------

在上周，客戶反應一個體系成績，當處置年夜量數據的時刻，湧現收集超時。後來，我們跟蹤測試，發明是因為索引碎片多而惹起的收集超時。

處理辦法，天然是從新組織和從新生成索引。在這裡，我寫了一個存儲進程sp_RefreshIndex來完成。

存儲進程sp_RefreshIndex:

use master
go
if object_id('sp_RefreshIndex') Is not null
    Drop Proc sp_RefreshIndex
Go
create proc sp_RefreshIndex
(
    @Reorganize_Fragmentation_Percent    smallint = 5    -- 當邏輯碎片百分比 > 5% 從新組織索引
    ,@Rebuild_Fragmentation_Percent        smallint = 30    -- 當邏輯碎片百分比 > 30% 從新生成索引
)
as
begin
    /* 挪用辦法：
.針對以後實例一切數據庫：    exec sys.sp_MSforeachdb 'use ?;exec sp_RefreshIndex'
.針對以後數據庫：            exec sp_RefreshIndex
    */

    --對體系數據庫不作從新組織索引和從新生成索引
    if (db_name() in ('master','model','msdb','tempdb')) return;

    --假如邏輯碎片（索引中的無序頁）的百分比 <= 5% ，就不作從新組織索引和從新生成索引
    if not exists(select 1 from sys.dm_db_index_physical_stats(db_id(),null,null,null,null) a where a.index_id>0 and a.avg_fragmentation_in_percent > @Reorganize_Fragmentation_Percent) return


    print replicate('-',60)+char(13)+char(10)+replicate(' ',14)+N'對數據庫 '+quotename(db_name())+N' 停止索引優化'+replicate(' ',20)+char(13)+char(10)

    declare @sql nvarchar(2000),@str nvarchar(2000)

    declare cur_x cursor for
        select 'alter index '+quotename(a.name)+' on '+quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+case when b.avg_fragmentation_in_percent<=@Rebuild_Fragmentation_Percent then ' reorganize;'else ' rebuild;'end as [sql]
                ,case when b.avg_fragmentation_in_percent<=@Rebuild_Fragmentation_Percent then N'從新組織索引：' else N'從新生成索引：'end +quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+'.'+quotename(a.name) as [str]
            from sys.indexes a
                inner join sys.dm_db_index_physical_stats(db_id(),null,null,null,null) b on b.object_id=a.object_id
                    and b.index_id=a.index_id
            where a.index_id>0
                and b.avg_fragmentation_in_percent > @Reorganize_Fragmentation_Percent
            order by object_name(a.object_id),a.index_id

    open cur_x
    fetch next from cur_x into @sql,@str

    while (@@fetch_status = 0)
    begin

        exec(@sql)
        print @str
        fetch next from cur_x into @sql,@str

    end
    close cur_x
    deallocate cur_x

end
go
exec sp_ms_marksystemobject 'sp_RefreshIndex'
go

挪用辦法：

use master
go
exec sys.sp_MSforeachdb 'use ?;exec sp_RefreshIndex'
go

注：我們依據現實的情況，修正@Reorganize_Fragmentation_Percent 和 @Rebuild_Fragmentation_Percent 值。