編寫SQL須要留意的細節Checklist總結

編寫SQL須要留意的細節Checklist總結。本站提示廣大學習愛好者：（編寫SQL須要留意的細節Checklist總結）文章只能為提供參考，不一定能成為您想要的結果。以下是編寫SQL須要留意的細節Checklist總結正文

---

/*
--留意：預備數據（可略過，異常耗時）
CREATE TABLE CHECK1_T1
(
ID INT,
C1 CHAR(8000)
)

CREATE TABLE CHECK1_T2
(
ID INT,
C1 CHAR(8000)
)

DECLARE @I INT
SET @I=1
WHILE @I<=10000
BEGIN
INSERT INTO CHECK1_T1 SELECT @I,'C1'
INSERT INTO CHECK1_T2 SELECT 10000+@I,'C1'

SET @I=@I+1
END

CREATE TABLE CHECK2_T1
(
ID INT,
C1 CHAR(8000)
)

DECLARE @I INT
SET @I=1
WHILE @I<=10000
BEGIN
INSERT INTO CHECK2_T1 SELECT @I,'C1'

SET @I=@I+1
END

INSERT INTO CHECK2_T1 VALUES(10001,'C2')

INSERT INTO CHECK2_T1 VALUES(10002,'C1')

CREATE TABLE CHECK3_T1
(
ID INT,
C1 CHAR(7000)
)

CREATE TABLE CHECK3_T2
(
ID INT,
C1 CHAR(7000)
)

DECLARE @I INT
SET @I=1
WHILE @I<=20000
BEGIN
IF @I%2 =0
BEGIN
INSERT INTO CHECK3_T1 SELECT @I,'C1'
END
ELSE
BEGIN
INSERT INTO CHECK3_T1 SELECT @I,'C2'
END

IF @I%100=0
BEGIN
INSERT INTO CHECK3_T2 SELECT @I,'C1'
INSERT INTO CHECK3_T2 SELECT @I+50000,'C2'
END
SET @I=@I+1
END


CREATE TABLE CHECK4_T1
(
ID INT,
C1 CHAR(500),
)

DECLARE @I INT
SET @I=1
WHILE @I<=500000
BEGIN
IF @I%100000 =0
BEGIN
INSERT INTO CHECK4_T1 SELECT @I,'C2'
END
ELSE
BEGIN
INSERT INTO CHECK4_T1 SELECT @I,'C1'
END

SET @I=@I+1
END
CREATE NONCLUSTERED INDEX NCIX_C1 ON CHECK4_T1(C1)

CREATE TABLE CHECK5_T1
(
ID INT,
C1 CHAR(10),
)


DECLARE @I INT
SET @I=1
WHILE @I<=10000
BEGIN
INSERT INTO CHECK5_T1 SELECT @I,'C1'
IF @I%2=0
BEGIN
INSERT INTO CHECK5_T1 SELECT @I,'C1'
END
SET @I=@I+1
END


*/
--=====================================
--1、 Union all 取代 Union

DBCC DROPCLEANBUFFERS
DBCC FREEPROCCACHE

--測試一：（26s） 履行籌劃：表掃描->排序->歸並聯接
SELECT ID,C1 FROM CHECK1_T1 --1W條數據
UNION
SELECT ID,C1 FROM CHECK1_T2 --1W條數據

--測試二： (4s) 履行籌劃：表掃描->表掃描串連
SELECT ID,C1 FROM CHECK1_T1 --1W條數據
UNION ALL
SELECT ID,C1 FROM CHECK1_T2 --1W條數據

--總結：測試一中的union 排序和去重歸並是相當耗時的，假如不要此功效，年夜數據時最好加上ALL

--=====================================
--2、 Exists 取代 Count(*)
DBCC DROPCLEANBUFFERS
DBCC FREEPROCCACHE

----測試一: （7s） 履行籌劃：表掃描-> 流聚合-> 盤算矢量
DECLARE @COUNT INT
SELECT @COUNT=COUNT(*) FROM CHECK2_T1 WHERE C1='C1' --1W條數據
IF @COUNT>0
BEGIN
PRINT 'S'
END
----測試二: （0s） 履行籌劃：常量掃描/表掃描-> 嵌套輪回-> 盤算標量
IF EXISTS(SELECT 1 FROM CHECK2_T1 WHERE C1='C1') --1W條數據
BEGIN
PRINT 'S'
END

--總結：斷定能否存在，用Exist便可，沒需要用COUNT(*)將表的一切記載統計出來，掃描一次

--=====================================
--3、 IN（Select COL1 From Table）的取代方法
DBCC DROPCLEANBUFFERS
DBCC FREEPROCCACHE

--測試一： （3s）履行籌劃：表掃描 -> 哈希婚配
SELECT ID,C1 FROM CHECK3_T2 --400行
WHERE ID IN (SELECT ID FROM CHECK3_T1 WHERE C1='C1') --2W行

--測試二：（1s）履行籌劃：表掃描-> 並行度 -> 位圖 -> 排序 -> 歸並聯接 -> 並行度
SELECT A.ID,A.C1 FROM CHECK3_T2 A
INNER JOIN CHECK3_T1 B ON A.ID=B.ID WHERE B.C1='C1'

--測試三：（3s）履行籌劃：表掃描-> 哈希婚配
SELECT A.ID,A.C1 FROM CHECK3_T2 A
WHERE EXISTS (SELECT 1 FROM CHECK3_T1 B WHERE B.ID=A.ID AND B.C1='C1')

--總結：能用INNER JOIN 盡可能用它，SQL SERVER在查詢時會將聯系關系表停止優化

--=====================================
--4、 Not Exists 取代 Not In
--測試一：（8s） 履行籌劃：表掃描-> 嵌套輪回 -> 哈希婚配
SELECT ID,C1 FROM CHECK3_T1 --2W行
WHERE ID NOT IN (SELECT ID FROM CHECK3_T2 WHERE C1='C1') --400行

--測試二：（4s） 履行籌劃：表掃描-> 哈希婚配
SELECT A.ID,A.C1 FROM CHECK3_T1 A
WHERE NOT EXISTS (SELECT 1 FROM CHECK3_T2 B WHERE B.ID=A.ID AND B.C1='C1')

--總結：盡可能不應用NOT IN ，由於會挪用嵌套輪回，建議應用NOT EXISTS取代NOT IN

--=====================================
--5、 防止在前提列上應用任何函數

DROP TABLE CHECK4_T1

CREATE NONCLUSTERED INDEX NCIX_C1 ON CHECK4_T1(C1) --加上非集合索引

---測試一：（4s）履行籌劃： 索引掃描
SELECT * FROM CHECK4_T1 WHERE RTRIM(C1)='C2'

---測試二：（0s）履行籌劃： 索引查找
SELECT * FROM CHECK4_T1 WHERE C1='C2'

--總結：where前提裡對索引字段應用了函數，會使索引查找釀成索引掃描，從而查詢效力年夜幅降低

--=====================================
--6、 用sp_executesql履行靜態sql

DBCC DROPCLEANBUFFERS
DBCC FREEPROCCACHE

CREATE PROC UP_CHECK5_T1 (
@ID INT
)
AS
SET NOCOUNT ON

DECLARE @count INT,
@sql NVARCHAR(4000)

SET @sql = 'SELECT @count=count(*) FROM CHECK5_T1 WHERE ID = @ID'

EXEC sp_executesql @sql,
N'@count INT OUTPUT, @ID int',
@count OUTPUT,
@ID

PRINT @count


CREATE PROC UP_CHECK5_T2 (
@ID INT
)
AS
SET NOCOUNT ON

DECLARE @sql NVARCHAR(4000)

SET @sql = 'DECLARE @count INT;SELECT @count=count(*) FROM CHECK5_T1 WHERE ID = ' + CAST(@ID AS VARCHAR(10)) + ';PRINT @count'

EXEC(@sql)


---測試一:瞬時
DECLARE @N INT
SET @N=1
WHILE @N<=1000
BEGIN
EXEC UP_CHECK5_T1 @N
SET @N=@N+1
END

---測試二:2s
DECLARE @N INT
SET @N=1
WHILE @N<=1000
BEGIN
EXEC UP_CHECK5_T2 @N
SET @N=@N+1
END

CREATE CLUSTERED INDEX CIX_ID ON CHECK5_T1(ID)

DBCC DROPCLEANBUFFERS
DBCC FREEPROCCACHE

--檢查緩存籌劃
SELECT a.size_in_bytes '占用字節數',
total_elapsed_time / execution_count '均勻時光',
total_logical_reads / execution_count '邏輯讀',
usecounts '重用次數',
SUBSTRING(d.text, (statement_start_offset / 2) + 1, ((CASE statement_end_offset
WHEN -1 THEN DATALENGTH(text)
ELSE statement_end_offset
END - statement_start_offset) / 2) + 1) '語句'
FROM sys.dm_exec_cached_plans a
CROSS apply sys.dm_exec_query_plan(a.plan_handle) c,
sys.dm_exec_query_stats b
CROSS apply sys.dm_exec_sql_text(b.sql_handle) d
WHERE a.plan_handle = b.plan_handle
ORDER BY total_elapsed_time / execution_count DESC;

--總結：經由過程履行上面緩存籌劃可以看出，第一種完整應用了緩存籌劃，查詢到達了很好的後果；
--而第二種則將緩存籌劃糟蹋了，招致緩存很快被占滿，這類做法是相當弗成取的

--=====================================
--7、 Left Join 的替換法
--測試一 履行籌劃：表掃描 -> 哈希婚配
SELECT A.ID,A.C1 FROM CHECK3_T1 A --2W行
LEFT JOIN CHECK3_T2 B ON A.ID=B.ID WHERE B.C1='C1' --400行

--測試二 履行籌劃：表掃描 -> 哈希婚配
SELECT A.ID,A.C1 FROM CHECK3_T1 A
RIGHT JOIN CHECK3_T2 B ON A.ID=B.ID WHERE a.C1='C1'

--測試三 履行籌劃：表掃描 -> 哈希婚配
SELECT A.ID,A.C1 FROM CHECK3_T1 A
INNER JOIN CHECK3_T2 B ON A.ID=B.ID WHERE B.C1='C1'

--總結：三條語句，在履行籌劃上完整一樣，都是走的INNER JOIN的籌劃，
--由於測試一和測試二中，WHERE語句都包括了LEFT 和RIGHT表的字段，SQLSERVER若發明只需有這個表的字段，則會主動依照INNER JOIN停止處置

--彌補測試：（1s）履行籌劃：表掃描-> 並行度 -> 位圖 -> 排序 -> 歸並聯接 -> 並行度
SELECT A.ID,A.C1 FROM CHECK3_T2 A --400行
INNER JOIN CHECK3_T1 B ON A.ID=B.ID WHERE A.C1='C1' --2W行
--總結：這裡有一個比擬風趣的處所，若主表和聯系關系表數據差異很年夜時，走的履行籌劃走的另外一條路

--=====================================
--8、 ON(a.id=b.id AND a.tag=3)
--測試一
SELECT A.ID,A.C1 FROM CHECK3_T1 A
INNER JOIN CHECK3_T2 B ON A.ID=B.ID AND A.C1='C1'

--測試二
SELECT A.ID,A.C1 FROM CHECK3_T1 A
INNER JOIN CHECK3_T2 B ON A.ID=B.ID WHERE A.C1='C1'

--總結：內銜接：不管是左表和右表的挑選前提都可以放到WHERE子句中

--測試一
SELECT A.ID,A.C1,B.C1 FROM CHECK3_T1 A
LEFT JOIN CHECK3_T2 B ON A.ID=B.ID AND B.C1='C1'

--測試二
SELECT A.ID,A.C1,B.C1 FROM CHECK3_T1 A
LEFT JOIN CHECK3_T2 B ON A.ID=B.ID WHERE B.C1='C1'

--總結：左外銜接:當右表中的過濾前提放入ON子句後和WHERE子句後的成果紛歧樣

--=====================================
--9、 賦值給變量，加Top 1
--測試一：（3s） 履行籌劃：表掃描
DECLARE @ID INT
SELECT @ID=ID FROM CHECK1_T1 WHERE C1='C1'
SELECT @ID

--測試二：（0s）履行籌劃：表掃描-> 前幾行
DECLARE @ID INT
SELECT TOP 1 @ID=ID FROM CHECK1_T1 WHERE C1='C1'
SELECT @ID

--總結：給變量賦值最好都加上TOP 1，一從查詢效力上加強，二為了精確性，若表CHECK1_T1有多個值，則會取最初一筆記錄賦給@ID

--=====================================
--10、 斟酌能否合適用CASE語句
DECLARE @S INT=1
SELECT * FROM CHECK5_T1
WHERE C1=(CASE @S WHEN 1 THEN C1 ELSE 'C2' END)

SELECT * FROM CHECK5_T1
WHERE @S=1 OR C1='C2'


/*--=====================================
、檢討語句能否須要Distinct. 履行籌劃：表掃描-> 哈希婚配-> 並行度-> 排序
select distinct c1 from CHECK3_T1
、禁用Select *，指定詳細列名
select c1 from CHECK4_T1
select * from CHECK4_T1
、Insert into Table（*）,指定詳細的列名
、Isnull,沒有需要的時刻不要對字段應用isnull，異樣會發生沒法有用應用索引的成績，
和防止在挑選列上應用函數異樣的道理。
、嵌套子查詢，加上查詢前提，確保子查詢的成果集最小
--=====================================*/