SQL中print、sp_helptext的限制與擴展

在SQL中，使用動態SQL是很常見的。有些復雜的計算，或是存儲過程，代碼很長，中間可能有多次執行SQL語句。而調試拼串的SQL語句卻是件痛苦的事，很難看出來運行的語句是什麼。所以我會經常使用print這個命令把運行前的語句打印到屏幕上，然後復制出來到另一個窗口進行調試、修改，這樣就比較方便了。但是這個print命令有一些限制,在單字節符集下，最大只能打印打印8000個字符的長度，而在雙字節字符集是4000個。

以下存儲過程可以打印完整的信息，不受長度的限制。代碼如下：

IF OBJECT_ID(N'sp_print_all') IS NOT NULL
BEGIN
DROP PROCEDURE sp_print_all
END
GO
CREATE PROCEDURE sp_print_all (@dynamic_sql NVARCHAR(MAX))
AS
DECLARE @start INT
DECLARE @len INT
SET @start = 1
SET @len = 4000
WHILE (@start < LEN(@dynamic_sql))
BEGIN
PRINT SUBSTRING(@dynamic_sql, @start, @len)
SET @start = @start + @len
END
PRINT SUBSTRING(@dynamic_sql, @start, @len)
GO 

code-1

還有一個存儲sp_helptext，可以查詢存儲過程，函數等代碼，使用起來也比較方便，但也有長度的限制，而且打印出來的格式跟源代碼的格式有些對應不上。寫了一個自定義存儲過程來代替，代碼如下：

IF OBJECT_ID(N'sp_helptext_user') IS NOT NULL
BEGIN
DROP PROCEDURE sp_helptext_user
END
GO
CREATE PROCEDURE sp_helptext_user(@obj_name NVARCHAR(200) = '')
AS
SET NOCOUNT ON;
DECLARE @text NVARCHAR(MAX)
,@i INT
,@text2 NVARCHAR(MAX)
,@db_name SYSNAME
,@obj_id BIGINT
SET @db_name = PARSENAME(@obj_name ,3)
IF @db_name IS NULL
SET @db_name = DB_NAME()
ELSE 
IF @db_name <> DB_NAME()
BEGIN
RAISERROR(15250 ,-1 ,-1)
RETURN (1)
END
SET @obj_id = OBJECT_ID(@obj_name)
IF @obj_id IS NULL
BEGIN
RAISERROR(15009 ,-1 ,-1 ,@obj_name ,@db_name)
RETURN (1)
END
SELECT @text = [definition]
FROM sys.all_sql_modules
WHERE [object_id] = @obj_id
WHILE LEN(@text) > 2000
BEGIN
SET @i = CHARINDEX(CHAR(13) ,@text ,2000) 
SET @text2 = LEFT(@text ,@i)
SET @text = SUBSTRING(@text ,@i + 2 ,LEN(@text)) 
PRINT @text2
END
PRINT @text
SET NOCOUNT OFF;
GO 

code-2

當然，查看源代碼有多種方法，可以在SSMS上操作等，看個人習慣或方便操作了。

詳解sp_helptext

顯示規則、默認值、未加密的存儲過程、用戶定義函數、觸發器或視圖的文本。

語法

sp_helptext [ @objname = ] 'name'

參數

[@objname =] 'name'

對象的名稱，將顯示該對象的定義信息。對象必須在當前數據庫中。name 的數據類型為 nvarchar(776)，沒有默認值。

返回代碼值

0（成功）或 1（失敗）

注釋

sp_helptext 在多個行中顯示用來創建對象的文本，其中每行有 Transact-SQL 定義的 255 個字符。這些定義只駐留在當前數據庫的 syscomments 表的文本中。

權限

執行權限默認授予 public 角色。

示例

下面的示例顯示 employee_insupd 觸發器的文本，該觸發器在數據庫 pubs 中。

USE pubs
EXEC sp_helptext 'employee_insupd'