數據庫發生阻塞和死鎖的現象：
一、數據庫阻塞的現象：第一個連接占有資源沒有釋放，而第二個連接需要獲取這個資源。如果第一個連接沒有提交或者回滾，第二個連接會一直等待下去，直到第一個連接釋放該資源為止。對於阻塞，數據庫無法處理，所以對數據庫操作要及時地提交或者回滾。
二、數據庫死鎖的現象：第一個連接占有資源沒有釋放，准備獲取第二個連接所占用的資源，而第二個連接占有資源沒有釋放，准備獲取第一個連接所占用的資源。這種互相占有對方需要獲取的資源的現象叫做死鎖。對於死鎖，數據庫處理方法：犧牲一個連接，保證另外一個連接成功執行。
例如，一個客戶端應用程序線程有兩個開放式連接。該線程異步啟動事務並在第一個連接上發出查詢。應用程序隨後啟動其它事務，在另一個連接上發出查詢並等待結果。當 SQL Server 返回其中一個連接的結果時，應用程序開始處理這些結果。應用程序就這樣處理結果，直到生成結果的查詢被另一個連接上執行的查詢阻塞而導致再沒有可用的結果為止。此時第一個連接阻塞，無限期等待處理更多的結果。第二個連接沒有在鎖上阻塞，但仍試圖將結果返回給應用程序。然而，由於應用程序阻塞而在第一個連接上等待結果，第二個連接的結果將得不到處理。
下面是查看並處理sql server 2000阻塞和死鎖的方法：
復制代碼 代碼如下:
use master --必須在master數據庫中創建
go
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_lockinfo]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_lockinfo]
GO
/*--處理死鎖
查看當前進程,或死鎖進程,並能自動殺掉死進程
因為是針對死鎖的,所以如果有死鎖進程,只能查看死鎖進程
當然,你可以通過參數控制,不管有沒有死鎖,都只查看死鎖進程
*/
/*--調用示例
exec p_lockinfo
--*/
create proc p_lockinfo
@kill_lock_spid bit=0, --是否殺掉死鎖的進程,1 殺掉, 0 僅顯示
@show_spid_if_nolock bit=1 --如果沒有死鎖的進程,是否顯示正常進程信息,1 顯示,0 不顯示
as
set nocount on
declare @count int,@s nvarchar(1000),@i int
select id=identity(int,1,1),標志,
進程ID=spid,線程ID=kpid,塊進程ID=blocked,數據庫ID=dbid,
數據庫名=db_name(dbid),用戶ID=uid,用戶名=loginame,累計CPU時間=cpu,
登陸時間=login_time,打開事務數=open_tran, 進程狀態=status,
工作站名=hostname,應用程序名=program_name,工作站進程ID=hostprocess,
域名=nt_domain,網卡地址=net_address
into #t from(
select 標志='死鎖的進程',
spid,kpid,a.blocked,dbid,uid,loginame,cpu,login_time,open_tran,
status,hostname,program_name,hostprocess,nt_domain,net_address,
s1=a.spid,s2=0
from master..sysprocesses a join (
select blocked from master..sysprocesses group by blocked
)b on a.spid=b.blocked where a.blocked=0
union all
select '|_犧牲品_>',
spid,kpid,blocked,dbid,uid,loginame,cpu,login_time,open_tran,
status,hostname,program_name,hostprocess,nt_domain,net_address,
s1=blocked,s2=1
from master..sysprocesses a where blocked<>0
)a order by s1,s2
select @count=@@rowcount,@i=1
if @count=0 and @show_spid_if_nolock=1
begin
insert #t
select 標志='正常的進程',
spid,kpid,blocked,dbid,db_name(dbid),uid,loginame,cpu,login_time,
open_tran,status,hostname,program_name,hostprocess,nt_domain,net_address
from master..sysprocesses
set @count=@@rowcount
end
if @count>0
begin
create table #t1(id int identity(1,1),a nvarchar(30),b Int,EventInfo nvarchar(255))
if @kill_lock_spid=1
begin
declare @spid varchar(10),@標志 varchar(10)
while @i<=@count
begin
select @spid=進程ID,@標志=標志 from #t where id=@i
insert #t1 exec('dbcc inputbuffer('+@spid+')')
if @@rowcount=0 insert #t1(a) values(null)
if @標志='死鎖的進程' exec('kill '+@spid)
set @i=@i+1
end
end
else
while @i<=@count
begin
select @s='dbcc inputbuffer('+cast(進程ID as varchar)+')' from #t where id=@i
insert #t1 exec(@s)
if @@rowcount=0 insert #t1(a) values(null)
set @i=@i+1
end
select a.*,進程的SQL語句=b.EventInfo
from #t a join #t1 b on a.id=b.id
order by 進程ID
end
set nocount off
go
通過的 Transact-SQL 將解決sql server 2000阻塞和死鎖問題
