在SQL Server中，視圖是一個保存的T-SQL查詢。視圖定義由SQL Server保存，以便它能夠用作一個虛擬表來簡化查詢，並給基表增加另一層安全。但是，它並不占用數據庫的任何空間。實際上，在你查詢它之前，視圖並不做任何事情。
索引視圖
在SQL Server 2000和2005中，你能夠給視圖增加索引。但是，如果視圖只是一個保存在數據庫中的查詢定義，在運行前沒有自己的數據，你如何給那個定義建立一個索引呢？嗯，這比較麻煩。
索引視圖是一個已被物化或保存在數據庫中的視圖。當基本表更新時，給視圖建立的索引由數據庫引擎保存和更新。當你的結果集返回許多行並且需要求總數時，索引視圖十分有用。這是因為數據庫引擎必須在基表數據更新時維持視圖索引，這可能會降低事務的性能。
要給一個視圖建立一個索引，視圖定義必須遵守某組條件和會話設置，同時要求把基表和視圖定義聯系起來。如果你確定你的視圖滿足這些標准（我將在後面討論這一點），你給視圖建立的第一個索引必須是一個唯一的聚集索引。建立的第一個視圖必須在一組欄上，並且被聚集，以便索引被物化。
下面代碼說明如何建立一個索引視圖。其中的腳本將建立SalesHistory表，並給它加載數據。
CREATE TABLE SalesHistory
(
SaleID INT IDENTITY(1,1),
Product VARCHAR(30),
SaleDate SMALLDATETIME,
SalePrice MONEY
)
DECLARE @i SMALLINT
SET @i = 1
WHILE (@i <=10000)
BEGIN
INSERT INTO SalesHistory
(Product, SaleDate, SalePrice)
VALUES
('Computer', DATEADD(mm, @i, '3/10/2006'),
DATEPART(ms, GETDATE()) + (@i + 57) )
INSERT INTO SalesHistory
(Product, SaleDate, SalePrice)
VALUES
('BigScreen', DATEADD(mm, @i, '3/2/2006'),
DATEPART(ms, GETDATE()) + (@i + 13) )
INSERT INTO SalesHistory
(Product, SaleDate, SalePrice)
VALUES
('PoolTable', DATEADD(mm, @i, '2/11/2007'),
DATEPART(ms, GETDATE()) + (@i + 29) )
SET @i = @i + 1
END
GO
下面的代碼將建立一個視圖來概括表中的數據：
CREATE VIEW vw_salesbyproduct
AS
SELECT
Product,
COUNT_BIG(*) as ProductCount,
SuM(SalePrice) as TotalSales
FROMdbo.SalesHistory
GROUP BY Product
由於它只是一個T-SQL查詢定義，建立這個視圖不用多少時間。建立好視圖後，你就可以像對一個表一樣對它進行查詢。
SELECT Product, TotalSales, ProductCount
FROM vw_SalesByProduct
WHERE product = 'Computer'
如果你在SQL Server Management Studio或Query Analyzer中設置選項來查看查詢的“執行計劃”（Execution Plan），你會注意到上面的查詢使用一個表掃描來找出Computer產品的總計結果。表掃描一般用於數據沒有索引的情況下，它對整個結果集進行掃描以找出需要的結果。
進行一些簡單的改變，你就能夠修改視圖，以便你可以給它增加一個索引，從而改善搜索性能。首先，你必須設定下面的會話設置：
SET ANSI_NULLS ON
GO
SET ANSI_PADDING ON
GO
SET ANSI_WARNINGS ON
GO
SET CONCAT_NULL_YIELDS_NULL ONGO
GO
SET QUOTED_IDENTIFIER ON
GO
SET NUMERIC_ROUNDABORT OFF
GO
現在你可以建立自己的視圖。為使事情更加簡單，我建立一個嶄新的視圖。
CREATE VIEW dbo.vw_SalesByProduct_Indexed
WITH SCHEMABINDING
AS
SELECT
Product,
COUNT_BIG(*) AS ProductCount,
SUM(ISNULL(SalePrice,0)) AS TotalSales
FROM dbo.SalesHistory
GROUP BY Product
GO
下面的腳本給我們的視圖建立索引：
CREATE UNIQUE CLUSTERED INDEX
idx_SalesVIEw ON vw_SalesByProduct_Indexed(Product)
為表明已經給視圖建立一個索引，並且它確實占用數據庫的空間，運行下面的腳本查明聚集索引有多少行以及視圖占用多少空間。
EXECUTE sp_spaceused 'vw_SalesByProduct_Indexed'
下面的SELECT語句和以前的語句相同，只是這次它執行一個聚集索引搜索，這個過程完成得非常快。
SELECT
Product, TotalSales, ProductCount
FROM vw_SalesByProduct_Indexed
WHERE Product = 'Computer'
不要忘記性能測試
索引視圖如果使用得當，它會十分有用，因為它們能夠顯著地提高查詢的性能。但是，由於聚集索引增加的性能，數據庫引擎必須在視圖基表的所有事務過程中維持那個索引。因為這個交換，建立一個索引視圖可能對系統有益，也可能給系統造成傷害。確定這樣做是有益還是有害的最佳方法就是進行全面的性能測試。
